@echo off
if "%1"=="" goto help
if "%1"=="protected" goto protected
if "%1"=="real" goto real
goto help

:protected
if "%2"=="notify" goto prot_say
if "%2"=="quiet" goto prot_quiet
goto help

:prot_say
echo Protected mode with notification
set blinker=/dt512 /hm+
goto end

:prot_quiet
echo Protected mode quiet
set blinker=/dt512 /hm-
goto end

:real
if "%2"=="notify" goto real_say
if "%2"=="quiet" goto real_quiet
goto help

:real_say
echo Real mode with notification
set blinker=/dt64000 /hm+
goto end

:real_quiet
echo Real mode quiet
set blinker=/dt64000 /hm-
goto end

:help
cls
echo The TDSET command invokes settings of Talking Directory needed before loading.
echo It takes two parameters, indicating memory mode and message notification.
echo The first parameter may be PROTECTED or REAL.
echo The second parameter may be NOTIFY or QUIET.
echo 
echo By default, TD will quietly load in protected mode, resorting to real mode
echo if it finds less than 512K of extended memory or less than a 286 processor.
echo Examples of commands to change this behavior follow:
echo 
echo tdset protected notify
echo will use protected mode and notify the user of the memory host found.
echo 
echo tdset real quiet
echo will use real mode and be quiet when loading.
goto end

:end
