0 RANDOMIZE VAL(RIGHT$(TIME$,5))
1 'COPYRIGHT 1977 BY W.A.BURTON-DO NOT COPY WITHOUT PERMISSION !
2 CLEAR 400
3 PRINT"               SLOT-MACHINE......."
4 PRINT"DO YOU WANT INSTRUCTIONS (Y OR N)":INPUT H$:cls
5 IF H$="Y" GOTO 85
6 IF H$="N" GOTO 7:GOTO 4
7 PRINT"         ---------- SILVER DOLLAR SLOT ----------"
8 B$="    BIG 7    "
9 C$="    -BAR-    "
10 D$="    $1OO     "
11 E$="    FIFTY    "
12 F$="     TEN     "
13 J$="    $5.OO    "
14 G$="    LEMON    "
15 W$="    -------       -------       -------"
16 P$="   -------------------------------------"
17 INPUT"WHAT IS YOUR LUCKY NUMBER (1 TO 25OOO)";K
18 IF K>25000 THEN 17
19 IF K<1 THEN 17
20 IF K<>INT(K) THEN 17
21 IF K<71 THEN K=K+77
22 P=K MOD 73
23 FOR O=1 TO P:O1=RND(7):NEXT O
24 INPUT"  YOUR BET ($1,$2 OR $3) ";M
25 L$="":M$="":N$=""
26 Y$="   ---- PAY LINE ----":X$="":Z$=""
27 IF M>1 THEN X$=Y$
28 IF M=3 THEN Z$=Y$
29 IF M=2 THEN Z$=""
30 IF M<1 THEN 34
31 IF M>3 THEN 34
32 IF M<>INT(M) THEN 34
33 GOTO 35
34 PRINT"INVALID BET, REENTER!!!":GOTO 24
35 M=-M
36 S=S+M:cls
37 FOR X=1 TO 9
38 A(X)=INT(RND(7)*101)
39 NEXT X
40 FOR Y=1 TO 9
41 IF A(Y)<2 THEN A$(Y)=B$ ELSE 43
42 GOTO 52
43 IF A(Y)<=5 THEN A$(Y)=C$ ELSE 45
44 GOTO 52
45 IF A(Y)<=13 THEN A$(Y)=D$ ELSE 47
46 GOTO 52
47 IF A(Y)<=26 THEN A$(Y)=E$ ELSE 49
48 GOTO 52
49 IF A(Y)<=55 THEN A$(Y)=F$ ELSE 51
50 GOTO 52
51 IF A(Y)<=94 THEN A$(Y)=J$ ELSE A$(Y)=G$
52 NEXT Y
53 IF A$(1)=G$ THEN A$(1)=J$
54 IF A$(2)=G$ THEN A$(2)=F$
55 IF A$(4)=G$ THEN A$(4)=E$
56 IF A$(5)=G$ THEN A$(5)=J$
57 IF A$(7)=G$ THEN A$(7)=F$
58 IF A$(8)=G$ THEN A$(8)=E$
59 N=1
60 IF X$<>Y$ THEN 63
61 IF A$(1)=A$(2) AND A$(2)=A$(3) THEN L$=" WINNER":GOSUB 78
62 IF A$(1)=A$(2) AND A$(3)=C$ THEN L$=" WINNER":GOSUB 78
63 N=4
64 IF A$(4)=A$(5) AND A$(5)=A$(6) THEN M$=" WINNER":GOSUB 78
65 IF A$(4)=A$(5) AND A$(6)=C$ THEN M$=" WINNER":GOSUB 78
66 IF Z$<>Y$ THEN 70
67 N=7
68 IF A$(7)=A$(8) AND A$(8)=A$(9) THEN N$=" WINNER":GOSUB 78
69 IF A$(7)=A$(8) AND A$(9)=C$ THEN N$=" WINNER":GOSUB 78
70 Q$=" "+A$(1)+" "+A$(2)+" "+A$(3)+" "+X$+L$
71 R$=" "+A$(4)+" "+A$(5)+" "+A$(6)+" "+Y$+M$
72 S$=" "+A$(7)+" "+A$(8)+" "+A$(9)+" "+Z$+N$
73 PRINT P$:PRINT Q$:PRINT W$:PRINT R$
74 PRINT W$:PRINT S$:PRINT P$:PRINT:PRINT
75 PRINT"           YOUR STANDING IS: $";S
76 PRINT:PRINT:PRINT:PRINT:PRINT
77 GOTO 24
78 IF A$(N)=B$ THEN S=S+7500
79 IF A$(N)=C$ THEN S=S+2500
80 IF A$(N)=D$ THEN S=S+100
81 IF A$(N)=E$ THEN S=S+50
82 IF A$(N)=F$ THEN S=S+10
83 IF A$(N)=J$ THEN S=S+5
84 RETURN
85 PRINT"GET THREE OF A KIND ON A 'PAY LINE' AND YOU WIN THAT AMOUNT"
86 PRINT"THREE 'BIG 7'S PAYS $75OO; THREE -BAR-S PAYS $25OO....."
87 PRINT
88 PRINT"ANY PAIR ON A LINE WITH A -BAR- IN THE THIRD POSITION PAYS"
89 PRINT"AS IF IT WERE THREE OF A KIND..."
90 PRINT"EXAMPLE:   $1OO   $1OO   -BAR- IS A $1OO.OO WINNER..."
91 PRINT
92 PRINT"IF YOU BET $1 ONLY THE CENTER LINE IS A 'PAY LINE'; IF"
93 PRINT"YOU BET $2 THE TOP TWO LINES ARE 'PAY LINES'; IF YOU BET $3"
94 PRINT"ALL THREE LINES ARE PAY LINES.
95 PRINT"ONLY WINNING COMBINATIONS ON A 'PAY LINE' WILL WIN MONEY..."
96 PRINT"THE 'LEMON' CANCELS THE PAYOFF ON ANY LINE ON WHICH IT APPEARS."
97 PRINT
98 PRINT"IF YOU HAVE BET MORE THAN $1, IT IS POSSIBLE TO HAVE MORE THAN"
99 PRINT"ONE SIMULTANEOUS PAYOFF......."
100 PRINT"EXAMPLE: IF YOU HAVE BET $2 AND YOU GET $5.OO SYMBOLS IN EACH"
101 PRINT"POSSIBLE POSITION, YOUR NET GAIN WOULD BE $1O MINUS YOUR $2"
102 PRINT"BET OR $8...YOU WOULD MISS AN ADDITIONAL $5 PAYOFF ON THE LAST"
103 PRINT"LINE BECAUSE YOU HAD ONLY BET $2......GOOD LUCK !!"
104 PRINT
105 GOTO 7
