0 RANDOMIZE TIMER
1 CLEAR 50
2 DEFINT A-Z:DEFSTR A,R,Y
3 CLS:PRINT CHR$(23)
4 PRINT "  THE HOUSE OF SEVEN GABLES"
5 PRINT 
6 PRINT "    BY GREG HASSETT"
7 A="I DON'T SEE IT HERE.":R="DON'T BE RIDICULOUS.":Y="I DON'T KNOW THAT WORD.":CP=2:GOTO 255
8 GOTO 248
9 IF INT(RND(1)*100)+1=50 AND ZZ>2 THEN 215
10 IF INT(RND(1)*40)+1=1 AND CP<>2 AND CP<>5 AND CP<>21 AND CP<>41 THEN 223
11 GOSUB 235:T=T+1:IF T=50 THEN OB$(27)="A TARNISHED OLD COMPASS"
12 IF NO>40 THEN NO=NO-40
13 IF VB<>25 AND VB>10 AND NO$="" THEN INPUT "GIVE ME AN OBJECT";NO$:GOSUB 244
14 IF NO$<>"" AND NO=0 AND VB=1 THEN PRINT "I DON'T UNDERSTAND THAT!":GOTO 11
15 IF T>175 THEN MI=MI-10
16 IF T>225 THEN MI=MI-15
17 IF NO=0 AND NO$<>"" THEN PRINT Y:GOTO 11
18 IF VB<>1 THEN 32
19 IF VB=1 AND NO$="" THEN INPUT "WHERE";NO$:GOSUB 244
20 IF NO>40 THEN NO=NO-40
21 IF NO<7 THEN 24 ELSE AB%=OB(NO,0)
22 IF (AB%>10 AND AB%<18) OR ABS(CP-AB%)>3 OR CP=2 OR AB%=0 THEN PRINT "I DON'T KNOW HOW TO APPLY THAT WORD HERE.":GOTO 11
23 CP=AB%:GOTO 8
24 IF OB(27,0)<>-1 THEN PRINT "I CAN'T UNDERSTAND COMPASS POINTS WITHOUT A COMPASS!":GOTO 11
25 IF P(CP,NO-1)=0 THEN PRINT "THERE IS NO WAY TO GO IN THAT DIRECTION.":GOTO 11
26 IF CP=2 AND NO=2 THEN PRINT "THE DOOR IS LOCKED. I THINK I CAN GET BY IT, THOUGH.":GOTO 11
27 IF CP=6 AND NO=3 AND DF=0 THEN PRINT "THE DOOR  TO THAT WAY IS CLOSED.":GOTO 11
28 IF CP=9 AND OB(9,0)=9 AND NO=1 THEN PRINT "THE VAMPIRE WON'T LET ME GO NORTH!":GOTO 11
29 IF CP=38 AND NO=6 AND OB(18,0)<>0 THEN P(5,0)=2
30 IF CP=5 AND FF=1 AND P(5,0)=2 AND NO=1 THEN CLS:PRINT "YOU MADE IT!":GOTO 230
31 CP=P(CP,NO-1):GOTO 8
32 IF VB<>2 THEN 48
33 IF NO$="" THEN INPUT "GET WHAT";NO$:GOSUB 244
34 IF OB(NO,0)=-1 THEN PRINT "I'M ALREADY CARRYING THAT!!!":GOTO 11
35 IF NO=7 AND CP=2 THEN PRINT "IT IS IMPOSSIBLE TO REMOVE.":GOTO 11
36 IF NO=0 THEN PRINT Y:GOTO 11
37 IF OB(NO,0)<>CP THEN PRINT A:GOTO 11
38 IF NO=31 THEN PRINT R:GOTO 11
39 IF NO=9 THEN PRINT "YOU CAN'T BE SERIOUS!":GOTO 11
40 IF NO=40 THEN PRINT "I CANNOT PULL IT OUT OF ITS SOCKET.":GOTO 11
41 IF NO=14 THEN PRINT "MY, THAT'S HEAVY. TOO HEAVY TO CARRY, IN FACT.":GOTO 11
42 IF NO=16 THEN PRINT "IT IS IN A BIG POT THAT I CAN'T lift.":GOTO 11
43 IF NO=22 THEN PRINT "BE SERIOUS.":GOTO 11
44 IF NO=26 THEN PRINT "THE CAT VANISHED, SAYING ";CHR$(34);"I WILL RETURN...";CHR$(34):OB(26,0)=INT(RND(1)*40)+1:GOTO 11
45 IF ZZ>5 THEN PRINT "I CAN'T CARRY ANY MORE. CLUE: DROP SOMETHING.":GOTO 11
46 ZZ=ZZ+1
47 OB(NO,0)=-1:PRINT "YOU GOT IT.":GOTO 11
48 IF VB=3 THEN 8
49 IF VB<>4 THEN 53
50 ZZ=0:PRINT "CURRENTLY I AM CARRYING:":FOR I=8 TO LO:IF OB(I,0)=-1 THEN PRINT OB$(I):ZZ=ZZ+1
51 NEXT I:IF ZZ=0 THEN PRINT "NOTHING!"
52 GOTO 11
53 IF VB<>5 THEN 58
54 J=0:FOR I=1 TO LO:IF OB(I,0)=5 THEN J=J+OB(I,1)
55 NEXT I:J=J+MI
56 PRINT "OUT OF A MAXIMUM OF 160 POINTS, YOU HAVE";J;"POINTS."
57 GOTO 11
58 IF VB<>6 THEN 65
59 IF NO$="" THEN INPUT "DROP WHAT";NO$:GOSUB 244
60 IF OB(NO,0)<>-1 THEN PRINT "I AM NOT HOLDING IT.":GOTO 11
61 PRINT "ALL RIGHT."
62 ZZ=ZZ-1
63 OB(NO,0)=CP
64 GOTO 11
65 IF VB=7 THEN PRINT "I CANNOT GIVE YOU HELP. IT IS AGAINST MY RELIGION.":GOTO 11
66 IF VB<>8 THEN 73
67 OPEN "GABLES.SAV" FOR OUTPUT AS 1
68 FOR I=8 TO LO:IF OB$(I)="" THEN 70
69 PRINT#1,OB(I,0)
70 NEXT I
71 PRINT #1,CP,FF,ZZ,T,P(5,0),DF
72 CLOSE:GOTO 11
73 IF VB<>9 THEN 80
74 OPEN "GABLES.SAV" FOR INPUT AS 1
75 FOR I=8 TO LO:IF OB$(I)="" THEN 77
76 INPUT #1,OB(I,0)
77 NEXT I
78 INPUT #1,CP,FF,ZZ,T,P(5,0),DF
79 CLOSE:GOTO 8
80 IF VB<>10 THEN 84
81 INPUT "DO YOU REALLY WANT TO QUIT NOW";QN$
82 QN$=LEFT$(QN$,1):IF QN$="N" THEN 11
83 GOTO 230
84 IF VB<>11 THEN 91
85 IF OB$(NO)="" AND NO<>7 THEN PRINT R:GOTO 11
86 IF NO=7 THEN 89
87 IF OB(NO,0)<>-1 THEN PRINT A:GOTO 11
88 IF NO<>7 THEN PRINT "I CAN'T RING ";OB$(NO);"!!":GOTO 11
89 IF CP<>2 THEN PRINT "I SEE NO BELL HERE!":GOTO 11
90 PRINT "THE DOOR FLIES OPEN AND I AM SWEPT INSIDE, BUT THEN THE DOOR VANISHES LEAVING NO VISIBLE WAY OUT!":FF=1:CP=5:GOTO 11
91 IF VB<>12 THEN 98
92 IF NO=8 AND OB(10,0)<>0 THEN PRINT "IT IS ALREADY FULL.":GOTO 11
93 IF OB(NO,0)<>-1 THEN PRINT "I'M NOT HOLDING IT RIGHT NOW.":GOTO 11
94 IF NO<>8 AND NO<>29 THEN PRINT "I CANT FILL THAT!":GOTO 11
95 IF CP<>3 THEN PRINT "THERE IS NOTHING TO FILL IT WITH HERE.":GOTO 11
96 IF NO=29 THEN PRINT "NO, I VALUE MY LIFE AND THAT FLUID THAT WAS IN THERE MIGHT REACT WITH THE WATER...":GOTO 11
97 IF NO=8 THEN PRINT "YOUR BUCKET IS NOW FULL.":OB(8,0)=0:OB(10,0)=-1:GOTO 11
98 IF VB<>13 THEN 104
99 IF NO<>27 AND NO<>26 AND NO<>9 AND NO<>13 AND NO<>31 THEN PRINT "IT ISN'T ALIVE!":GOTO 11
100 IF OB(NO,0)<>CP THEN PRINT A:GOTO 11
101 IF NO=9 THEN PRINT "I DON'T THINK IT WOULD APPROVE.":GOTO 11
102 IF NO=27 THEN PRINT "IT DOESN'T TAKE TOO FAVORABLY TO THE IDEA.":GOTO 11
103 PRINT "YOU'LL HAVE TO BE MORE SPECIFIC.":GOTO 11
104 IF VB<>14 THEN 110
105 IF NO=0 THEN PRINT "THROW WHAT?":GOTO 11
106 IF OB(NO,0)<>-1 THEN PRINT "I'M NOT HOLDING IT!":GOTO 11
107 IF NO<>24 AND NO<>10 THEN 60
108 IF CP=38 AND NO=10 THEN PRINT "THE WITCH HAS VANISHED!":OB(18,0)=38:PRINT "HER HAT REMAINS.":OB(31,0)=0:OB(10,0)=0:OB(8,0)=-1:GOTO 11
109 GOTO 60
110 IF VB<>15 THEN 116
111 IF NO=0 THEN PRINT "SHOW WHAT?":GOTO 11
112 IF OB(NO,0)<>-1 THEN PRINT "I'M NOT CARRYING IT!":GOTO 11
113 IF NO<>11 THEN PRINT "NOTHING HAPPENED.":GOTO 11
114 IF OB(9,0)<>25 THEN PRINT "NOTHING EXCITING HAPPENED.":GOTO 11
115 PRINT "THE VAMPIRE SCURRIES OFF SAYING: YOU HAVEN'T SEEN THE END OF ME YET!!!":OB(9,0)=9:GOTO 11
116 IF VB<>16 THEN 123
117 IF NO<>9 AND NO<>13 AND NO<>31 THEN PRINT "THAT IS STUPID.":GOTO 11
118 IF OB(NO,0)<>CP THEN PRINT A:GOTO 11
119 IF OB(23,0)<>-1 THEN PRINT "I DON'T HAVE ANY FOOD, STUPID!":GOTO 11
120 IF NO=9 AND OB(23,0)<>-1 THEN PRINT "HE ONLY LIKES BANANAS.":GOTO 11
121 IF NO=9 THEN PRINT "HE WOLFS DOWN YOUR BANANA AND EATS THE PEEL, TOO!":OB(23,0)=0:GOTO 11
122 PRINT "SHE GRABS THE BANANA AND THROWS IT IN TO THE BREW.":OB(23,0)=0:GOTO 11
123 IF VB<>17 THEN 129
124 IF OB(NO,0)<>-1 AND OB(NO,0)<>CP THEN PRINT "I DON'T SEE IT HERE.":GOTO 11
125 IF NO=11 THEN PRINT "I DON'T WANT TO HAVE BAD BREATH.":GOTO 11
126 IF NO<>12 AND NO<>23 THEN PRINT R:GOTO 11
127 IF OB(NO,0)<>-1 THEN PRINT "I'M NOT CARRYING IT.":GOTO 11
128 PRINT "MUNCH MUNCH MUNCH. GOOD.":OB(23,0)=0:OB(24,0)=-1:GOTO 11
129 IF VB<>18 THEN 141
130 IF NO=0 THEN PRINT "JE NE COMPRENDS PAS. (I DON'T UNDERSTAND ).":GOTO 11
131 IF NO<>14 AND NO<>22 AND NO<>33 THEN PRINT "THAT IS BEYOND MY CAPABILITIES.":GOTO 11
132 IF CP<>25 AND NO=14 THEN PRINT "I SEE NO COFFIN TO OPEN HERE!":GOTO 11
133 IF CP=25 AND OB(9,0)=CP AND NO=14 THEN PRINT "THE VAMPIRE WON'T LET ME!":GOTO 11
134 IF NO=14 AND CP=25 THEN PRINT "THE COFFIN IS OPEN":CF=1:IF OB(35,0)=0 THEN OB(35,0)=25:GOTO 11 ELSE 11
135 IF NO<>22 THEN 139
136 IF CP=2 THEN PRINT "IT IS LOCKED. MAYBE THESE PEOPLE(?) ARE FRIENDLY, SO TRY RINGING THE BELL.":GOTO 11
137 IF CP=6 THEN PRINT "I CANNOT. THERE IS NO DOOR KNOB AND NO KEYHOLE. HOWEVER, IT IS QUITE POSSIBLE THAT I CAN GET BY IT.":GOTO 11
138 PRINT "I SEE NO DOOR HERE.":GOTO 11
139 IF OB(33,0)=-1 THEN PRINT "TRY UNFOLD AIRPLANE." ELSE PRINT "I HAVE NO AIRPLANE."
140 GOTO 11
141 IF VB<>20 THEN 150
142 IF NO=22 AND (CP=2 OR CP=6) THEN 145
143 IF NO=0 THEN PRINT "CHOP WHAT? I DON'T UNDERSTAND !":GOTO 11
144 IF OB(NO,0)<>CP THEN PRINT "I DON'T SEE IT HERE.":GOTO 11
145 IF OB(39,0)<>-1 THEN INPUT "WITH WHAT, MY BARE HANDS";BH$:IF LEFT$(BH$,1)="Y" THEN PRINT "I DON'T KNOW KARATE!":GOTO 11
146 IF OB(39,0)<>-1 THEN PRINT "ALL RIGHT THEN !":GOTO 11
147 IF NO<>22 THEN PRINT "THAT IS BEYOND MY POWER.":GOTO 11
148 IF CP<>2 AND CP<>6 THEN PRINT "I SEE NO DOOR HERE.":GOTO 11
149 PRINT "THE DOOR IS CHOPPED TO PEICES.":DF=1:GOTO 11
150 IF VB<>19 THEN 158
151 IF NO<>22 AND NO<>38 AND NO<>14 THEN PRINT "THAT IS RIDICULOUS.":GOTO 11
152 IF NO=14 AND CP<>25 THEN PRINT "I SEE NO COFFIN TO CLOSE HERE.":GOTO 11
153 IF NO=14 AND CP=25 THEN PRINT "THE COFFIN IS CLOSED.":CF=0:GOTO 11
154 IF NO=22 AND CP=2 THEN PRINT "IT IS ALREADY CLOSED.":GOTO 11
155 IF NO=22 AND CP=5 THEN PRINT "THE DOOR VANISHED, REMEMBER?":GOTO 11
156 IF NO=22 AND CP=6 AND DF=1 THEN PRINT "CLOSING A BUNCH OF WOOD SCRAPS IS BEYOND BY POWER.":GOTO 11
157 IF NO=22 THEN PRINT "I SEE NO DOOR HERE.":GOTO 11
158 IF VB<>21 THEN 163
159 IF NO=0 THEN PRINT Y:GOTO 11
160 IF NO<>15 THEN PRINT "WHY DO YOU KEEP TELLING ME TO DO DUMB THINGS?":GOTO 11
161 IF OB(15,0)<>-1 THEN PRINT "I'M NOT HOLDING THEM!":GOTO 11
162 PRINT "OKAY... POOF! THE CHEMICALS TRANSFORMED THEMSELVES IN TO AN OR ANGE BUBBLING LIQUID.":CF=1:GOTO 11
163 IF VB<>22 THEN 179
164 IF NO<>16 AND NO<>10 AND NO<>28 AND NO<>15 THEN PRINT "YOU CAN'T BE SERIOUS.":GOTO 11
165 IF NO=16 AND CP=38 THEN PRINT "I DON'T THINK I SHOULD. (THERE'S AN OLD SHOE IN IT!)":GOTO 11
166 IF NO=10 AND OB(10,0)=-1 THEN PRINT "OKAY! GULP GULP GULP.":OB(10,0)=0:OB(8,0)=-1:GOTO 11
167 IF NO=28 AND OB(28,0)=-1 THEN PRINT "ALL RIGHT. POOF! OH MY! WHERE AM I?? OH MY! ALL MY POSESSIONS WERE LOST IN THE DENSE CLOUD OF GREASY BLACK SMOKE."
168 IF NO<>28 OR OB(28,0)<>-1 THEN 177
169 FOR I=8 TO LO
170 IF OB$(I)="" THEN 173
171 IF OB(I,0)<>-1 AND OB(I,O)<>5 THEN 173
172 OB(I,0)=INT(RND(1)*38)+1
173 NEXT I
174 OB(28,0)=0:OB(29,0)=-1
175 ZZ=1
176 GOTO 11
177 IF NO=15 THEN PRINT "I DON'T WANT TO TRY THAT.":GOTO 11
178 PRINT "I CAN'T DO THAT YET.":GOTO 11
179 IF VB<>23 THEN 185
180 IF NO=22 AND (CP=2 OR CP=6) THEN 182
181 IF OB(NO,0)<>-1 AND OB(NO,0)<>CP THEN PRINT "I DON'T SEE IT HERE.":GOTO 11
182 IF NO<>9 AND NO<>13 AND NO<>31 THEN PRINT "I DON'T WANT TO HIT THE ";NO$;".":GOTO 11
183 IF NO=9 THEN PRINT "HIT HIM YOURSELF! I'M SURE NOT GONNA!":GOTO 11
184 PRINT "YUK! SHE'S GOT WARTS ALL OVER HER!":GOTO 11
185 IF VB=24 THEN PRINT "ALL RIGHT...";NO$:GOTO 11
186 IF VB=25 THEN PRINT "YOU HAVE USED";T;"TURNS SO FAR.":GOTO 11
187 IF VB<>26 THEN 193
188 IF NO<>10 AND NO<>28 AND NO<>15 THEN PRINT "DON'T BE DUMB.":GOTO 11
189 IF NO=10 AND OB(10,0)=-1 THEN PRINT "YOUR BUCKET IS EMPTY AND THE GROUND IS WET.":OB(10,0)=0:OB(8,0)=-1:GOTO 11
190 IF NO=28 THEN PRINT "YOU ARE STUCK WITH AN EMPTY TEST TUBE NOW.":OB(28,0)=0:OB(29,0)=-1:GOTO 11
191 IF NO=15 AND OB(15,0)=-1 THEN PRINT "THE CHEMICALS REACTED WITH THE DUST AND I GOT LOST IN A THICK CLOUD OF OR ANGE SMOKE. I SUGGEST YOU 'LOOK'.":CP=12:GOTO 11
192 PRINT "I AM NOT CARRYING IT RIGHT NOW.":GOTO 11
193 IF VB=27 THEN PRINT "I'M NOT ROCKY, YOU KNOW.":GOTO 11
194 IF VB<>29 THEN 198
195 IF NO<>33 THEN PRINT "GIVE ME A BREAK!":GOTO 11
196 IF OB(33,0)<>-1 THEN PRINT "I'M NOT HOLDING AN AIRPLANE!":GOTO 11
197 PRINT "OK.":OB(33,0)=0:OB(34,0)=-1:GOTO 11
198 IF VB<>28 THEN 205
199 IF OB(NO,0)<>CP AND OB(NO,0)<>-1 THEN PRINT "I DON'T SEE IT AND I'M NOT HOLDING IT.":GOTO 11
200 IF NO<>34 AND NO<>32 AND NO<>19 THEN PRINT "THERE IS NO WRITING THERE.":GOTO 11
201 IF OB(NO,0)<>-1 THEN PRINT "I DON'T HAVE IT WITH ME.":GOTO 11
202 IF NO=32 THEN PRINT "IT SAYS: NOTTUB SSERP":GOTO 11
203 IF NO=34 THEN PRINT "IT READS: REMEMBER THE WIZARD OF OZ.":GOTO 11
204 PRINT "THEY ARE WRITTEN IN WITCHISH.":GOTO 11
205 IF VB=30 THEN PRINT "TRY OPEN.":GOTO 11
206 IF VB<>31 THEN 212
207 IF OB(NO,0)<>CP THEN PRINT A:GOTO 11
208 IF NO<>9 AND NO<>31 THEN PRINT "BE SERIOUS.":GOTO 11
209 IF OB(35,0)<>-1 THEN PRINT "I DON'T HAVE A KNIFE!":GOTO 11
210 IF NO=31 THEN PRINT "THE KNIFE VANISHES WHEN IT TOUCHES HER.":OB(35,0)=0:GOTO 11
211 PRINT "THE VAMPIRE DIES AND  THEN VANISHES.":OB(9,0)=0:GOTO 11
212 IF NO<>40 THEN PRINT "THAT'S IDIOTIC.":GOTO 11
213 IF CP<>37 THEN PRINT "I SEE NO button HERE.":GOTO 11
214 CP=38:GOTO 8
215 PRINT "OH MY! A GHOST POPS OUT AND SAYS: THROW ME SOME TREASURE!":GOSUB 235
216 IF VB<>16 OR NO<>13 THEN 218
217 IF OB(23,0)=0 THEN PRINT "I HAVE NO FOOD." ELSE PRINT "HE EATS THE BANANA AND VANISHES.":OB(23,0)=0:OB(24,0)=CP:GOTO 11
218 IF VB<>14 THEN PRINT "HE IS GETTING MAD!":GOSUB 235
219 IF VB<>14 THEN PRINT "HE HAS KILLED ME!":GOTO 230
220 IF OB(NO,0)<>-1 THEN PRINT "I'M NOT HOLDING IT.":GOSUB 235:GOTO 218
221 IF OB(NO,1)=0 THEN PRINT "HE GROWLS: NOT GOOD ENOUGH! AND THROWS IT BACK.":GOSUB 235:GOTO 218
222 PRINT "HE SNATCHES THE TREASURE AND RUNS AWAY.":ZZ=ZZ-1:OB(NO,0)=0:GOTO 11
223 PRINT "HEAVENS! A ONE EYED GHOUL POPPED OUT!"
224 INPUT "WHAT AM I TO DO";CM$:GOSUB 236
225 IF VB<>14 OR NO<>15 THEN 229
226 IF OB(15,0)<>-1 THEN PRINT "I DON'T HAVE THEM!":GOTO 229
227 IF CF=0 THEN PRINT "THEY WEREN'T MIXED!":GOTO 229
228 PRINT "THE GHOUL MELTS TO NOTHING.":OB(15,0)=CP:GOTO 11
229 PRINT "THE GHOUL KILLS ME!":GOTO 230
230 J=0:FOR I=8 TO LO:IF OB(I,0)=5 THEN J=J+OB(I,1)
231 NEXT I
232 J=J+MI
233 PRINT "OUT OF A MAXIMUM OF 160 POINTS, YOU SCORED";J;"POINTS, USING";T;"TURNS.":PRINT :INPUT "DO YOU WISH TO PLAY THIS ADVENTURE AGAIN";AG$:AG$=LEFT$(AG$,1):IF AG$="Y" THEN RUN ELSE IF AG$<>"N" THEN 230
234 END
235 INPUT "WHAT SHOULD I DO";CM$:CLS
236 NO$="":VB$="":VB=0:NO=0
237 LC=LEN(CM$):FOR I=1 TO LC:IF MID$(CM$,I,1)<>" " THEN VB$=VB$+MID$(CM$,I,1):NEXT I
238 V1$=VB$
239 VB$=LEFT$(VB$,3)
240 FOR I=1 TO NV:IF VB$(I)=VB$ THEN VB=I:GOTO 242 ELSE NEXT I
241 VB=1:NO$=VB$:GOTO 244
242 IF LEN(V1$)+1>=LEN(CM$) THEN NO=0:RETURN
243 NO$=RIGHT$(CM$,LEN(CM$)-1-LEN(V1$))
244 NO$=LEFT$(NO$,3):FOR I=1 TO NN:IF NO$=NO$(I) THEN 246 ELSE NEXT I
245 NO=0:RETURN
246 NO=I:RETURN
248 PRINT P$(CP)
249 FOR I=8 TO LO:IF OB(I,0)=CP THEN PRINT "THERE IS ";OB$(I);" HERE."
250 NEXT I
251 FL=0:IF OB(27,0)<>-1 THEN 253 ELSE PRINT "I CAN GO -- ";:FOR I=0 TO 5:IF P(CP,I)<>0 THEN PRINT NO$(41+I);" ";:FL=1
252 NEXT I:IF FL=0 THEN PRINT "NOWHERE!" ELSE PRINT 
253 PRINT
254 GOTO 9
255 NN=46:LO=40:P=40:NV=32:DIM NO$(NN),OB$(LO),OB(LO,1),P$(P),P(P,5),VB$(NV)
256 P$(1)="I'M AT THE SECOND GABLE.":DATA 0,4,0,0,0,0
257 P$(2)="I'M OUTSIDE A HOUSE WITH SEVEN GABLES. THERE IS A DOOR BELL BESIDE THE DOOR .":DATA 0,5,0,0,0,0
258 P$(3)="I'M IN THE KITCHEN. THERE IS A SINK WITH A WORKING SPICKET HERE.":DATA 0,6,0,0,0,0
259 P$(4)="I'M IN THE GUEST ROOM. (I DON'T WANT TO BE A PERMANENT GUEST!)":DATA 1,0,5,8,0,0
260 P$(5)="I'M IN THE LIVING ROOM.":DATA 0,9,6,4,0,0
261 P$(6)="I'M IN THE DINING ROOM.":DATA 3,0,7,5,0,0
262 P$(7)="I'M AT THE BOTTOM OF A STAIRWELL.":DATA 0,0,0,6,29,0
263 P$(8)="I'M AT THE FIRST GABLE. IT OVERLOOKS A HUGE YARD OF TALL GRASS.":DATA 0,0,4,0,0,0
264 P$(9)="I'M AT THE TOP OF A STAIRCASE.":DATA 5,0,0,10,0,20
265 P$(10)="I'M IN A DARK STORAGE CLOSET. A HOLLOW VOICE SAYS: MIX THEM.":DATA 0,0,9,0,0,0
266 P$(11)="I'M IN A MAD SCIENTIST'S LABORATORY.":DATA 0,0,0,0,0,12
267 P$(12)="I'M IN A MAZE OF HALLWAYS.":DATA 0,16,12,12,11,15
268 DATA 0,0,0,0,0,0,0,0,0,0,0,0
269 P$(15)=P$(12):DATA 15,17,15,16,0,0
270 P$(16)=P$(12):DATA 15,16,12,16,16,16
271 P$(17)=P$(12):DATA 15,0,18,0,0,0
272 P$(18)="I'M AT THE WEST END OF THE HALLWAY":DATA 19,0,23,17,0,0
273 P$(19)="I'M IN A DUNGION. A CRUDE NOTE ON THE WALL READS: YOU CAN'T GET OUT WITHOUT KILLING ME FIRST! --WITCHY-POO":DATA 0,18,19,19,19,19
274 P$(20)="I'M AT THE BOTTOM OF A STAIRCASE.":DATA 0,23,0,0,9,0
275 DATA 0,0,0,0,0,0
276 P$(22)="I'M IN A BARREN LIBRARY.":DATA 0,24,0,0,0,0
277 P$(23)="I'M IN THE CENTER OF A LONG E/W HALLWAY":DATA 20,0,24,18,0,0
278 P$(24)="I'M AT THE EAST END OF THE HALLWAY.":DATA 22,0,25,23,0,0
279 P$(25)="I'M IN DRACULA'S CHAMBER":DATA 0,0,0,24,0,0
280 P$(26)="I'M IN A BROOM CLOSET. EXCITING.":DATA 0,0,0,27,0,0
281 P$(27)="I'M AT THE FOURTH GABLE":DATA 28,0,0,26,0,0
282 P$(28)="I'M AT GABLE FIVE.":DATA 0,27,29,0,0,0
283 P$(29)="I'M AT THE TOP OF A STAIRCASE.":DATA 0,0,0,28,0,32
284 P$(30)="I'M IN A BEDROOM.":DATA 0,0,31,33,0,0
285 P$(31)="I'M IN A DUSTY OLD CHAMBER. LOOKS LIKE A DILAPIDATED BEDROOM.":DATA 0,34,32,30,0,0
286 P$(32)="I'M AT THE SIXTH GABLE.":DATA 0,0,0,31,0,0
287 P$(33)="I'M AT THE THIRD GABLE.":DATA 0,0,34,30,0,0
288 P$(34)="I'M AT ONE END OF A HALLWAY.":DATA 31,40,35,0,0,0
289 P$(35)="I'M IN THE MIDDLE OF A HALLWAY.":DATA 0,0,36,34,0,0
290 P$(36)=P$(34):DATA 32,0,37,35,0,0
291 P$(37)="I'M IN A ROOM WITH A PEDESTAL IN THE MIDDLE. ATOP THE PEDESTAL IS A LARGE BUTTON.":DATA 0,0,0,36,0,39
292 P$(38)="I'M IN THE WITCH'S CHAMBER.":DATA 0,0,0,0,0,5
293 P$(39)="I'M AT THE SEVENTH GABLE":DATA 37,0,0,0,0,0
294 P$(40)="I'M AN A MAMOTH ART GALLERY.":DATA 34,0,0,0,0,0
295 OB$(8)="AN EMPTY BUCKET":DATA 6,0:OB$(9)="A MEAN LOOKING VAMPIRE":DATA 25,0:OB$(10)="A BUCKET OF WATER":DATA 0,0
296 OB$(11)="SOME FRESH GARLIC":DATA 3,0
297 OB$(14)="A COFFIN":DATA 25,0:OB$(15)="SOME CHEMICALS":DATA 11,0
298 OB$(16)="A POT OF WITCHES' BREW":DATA 38,0
299 OB$(18)="A BLACK HAT":DATA 0,50:OB$(19)="SOME VALUABLE RECIPES":DATA 26,15
300 OB$(20)="SOME SILVER CANDLESTICKS":DATA 6,10
301 OB$(23)="A BANANA":DATA 3,0:OB$(24)="A BANANA PEEL":DATA 0,0
302 OB$(25)="A SPARKLING DIAMOND":DATA 39,15:OB$(26)="A BLACK CAT":DATA 1,0
303 OB$(27)="A SHINY COMPASS":DATA 2,0
304 OB$(28)="A TEST TUBE OF FLUID":DATA 33,0:OB$(29)="AN EMPTY TEST TUBE":DATA 0,0
305 OB$(30)="A BEAUTIFUL ROSE":DATA 29,10:OB$(31)="AN UGLY WITCH":DATA 38,0:OB$(32)="A BOOK TITLED PRIMEVAL WITCHCRAFT":DATA 22,0
306 OB$(33)="A PAPER AIRPLANE":DATA 32,0:OB$(34)="A PIECE OF PAPER WITH WRITING ON IT":DATA 0,0
307 OB$(35)="SULTON'S DAGGER":DATA 0,35:OB$(36)="A PRICELESS REMBRANT":DATA 40,20
308 OB$(39)="AN OLD RUSTY AXE":DATA 15,5
309 FOR I=1 TO P:FOR J=0 TO 5:READ P(I,J):NEXT J,I
310 FOR I=8 TO LO
311 IF OB$(I)="" THEN 313
312 READ OB(I,0),OB(I,1)
313 NEXT I
314 DATA NOR,SOU,EAS,WES,UP,DOW,BEL,BUC,VAM,WAT,GAR,FOO,GHO,COF,CHE,BRE,CUP,HAT,REC,CAN,KEY,DOO,BAN,PEE,DIA,CAT,COM,FLU,TUB,ROS,WIT,BOO,AIR,PAP,DAG,REM,CAG,GAT,AXE,BUT,N,S,E,W,U,D
315 FOR I=1 TO NN:READ NO$(I):NEXT I
316 DATA GO,GET,LOO,INV,SCO,DRO,HEL,SAV,LOA,QUI,RIN,FIL,KIL,THR,SHO,FEE,EAT,OPE,CLO,CHO,MIX,DRI,HIT,SAY,TUR,DUM,FIG,REA,UNF,UNL,STA,PRE
317 FOR I=1 TO NV:READ VB$(I):NEXT I
318 GOTO 8
