100 REM EXECUTIVE DECISION MAKER
101 REM WRITTEN BY W.A.BURTON
102 REM INTENDED FOR CRT'S AT HIGH BAUD RATES
103 CLEAR:WIDTH 80 :cls
104 DIM Q$(80):XX=36
105 PRINT TAB(15); "*** EXECUTIVE DECISION MAKER ***"
106 PRINT:PRINT:PRINT
107 PRINT "WHAT IS THE DECISION THAT YOU WOULD LIKE ME TO MAKE FOR YOU"
108 PRINT "TYPE IN YOUR QUESTION WHICH CAN BE ANSWERED 'YES OR NO'; AND"
109 PRINT "KEEP IT SHORTER THAN ONE LINE (INCLUDING SPACES)."
110 PRINT:PRINT:PRINT:PRINT
111 INPUT Q$
112 PRINT:PRINT
113 REM THIS IS A 'PSEUDO-RANDOMIZE' ROUTINE
114 FOR X=1 TO LEN(Q$)
115 Z$=MID$(Q$,X,1)
116 Z=ASC(Z$)
117 Y=Y+Z
118 NEXT X
119 Y=Y MOD 97
120 FOR X=1 TO Y
121 Z=RND(1):Z1=RND(Y)
122 NEXT X
123 A$="<*>":AL$="YES :":AR$=": NO"
124 PRINT "THE '<*>' IS THE BOUNCING BALL OF FATE..."
125 PRINT "HIT SPACE BAR TO ANSWER YOUR QUESTION"
126 PRINT:PRINT:PRINT
127 PRINT TAB(10); AL$; TAB(XX); A$; TAB(61); AR$
128 WAIT 0,1,1
129 PRINT TAB(10); AL$; TAB(XX); A$; TAB(61); AR$
130 W=RND(1)
131 IF W<.5 THEN XX=XX+2 ELSE XX=XX-2
132 IF XX<16 THEN cls:GOTO 136
133 IF XX>=59 THEN cls:GOTO 139
134 CX=CX+1
135 GOTO 129
136 GOSUB 142
137 PRINT "YES"
138 GOTO 147
139 GOSUB 142
140 PRINT "NO"
141 GOTO 147
142 PRINT:PRINT
143 PRINT "YOUR QUESTION :"
144 PRINT Q$:PRINT
145 PRINT "MY ANSWER (AFTER"; CX; "AGONIZING STEPS) :"
146 RETURN
147 PRINT:PRINT
148 PRINT "DO YOU NEED HELP IN MAKING ANOTHER DECISION (Y OR N)"
149 INPUT Q$
150 IF LEFT$(Q$,1)="Y" THEN RUN
151 cls:END
