10 DATA ASTRON,STAR,AUTOS,SELF,BIOS,LIFE,CHRONOS,TIME:
20 DATA DECA,TEN,DEMOS,PEOPLE,GE,EARTH,GRAPHO,WRITE:  
30 DATA LITHOS,STONE,METRON,MEASURE,MONOS,ONE,ORTHOS: 
40 DATA RIGHT,PHILOS,LOVING,PHONE,SOUND,POLYS,MANY:   
50 DATA SCOPOS,WATCHER,TELE,FAR,THERMO,HEAT:  
60 DATA ZOON,ANIMAL,ANTHROPOS,MAN:
70 RANDOMIZE TIMER
100 REM  
110 REM DESCRIPTION--TESTS KNOWLEDGE OF ENGLISH TRANSLATION OF   
120 REM   GREEK ROOTS
130 REM  
140 REM SOURCE--UNKNOWN  
150 REM  
160 REM INSTRUCTIONS--TYPE "RUN" AND RESPOND TO TEST QUESTIONS   
170 REM  
180 DIM A$(40) 
190 FOR I=1 TO 40
200 READ A$(I) 
210 NEXT I 
220 PRINT "WHAT IS YOUR NAME"; 
230 INPUT N$   
240 PRINT "THESE GREEK ROOTS ARE FOUND IN MANY SCIENTIFIC TERMS."  
250 PRINT "YOU WILL BE ASKED TO GIVE A ONE WORD MEANING FOR EACH"  
260 PRINT "ROOT AND GET 10 POINTS FOR EACH CORRECT ANSWER. THE COMPUTER"   
270 PRINT "WILL KEEP SCORE. GOOD LUCK, " ;N$   
280 PRINT  
290 FOR I=0 TO 30 STEP 10
300 PRINT A$(I+1);" ";A$(I+3);" ";A$(I+5);" ";A$(I+7);" ";A$(I+9)
310 NEXT
350  H=0
360 Z= 20  
370 X = 2*INT(Z*RND(1)+1)  
380 PRINT "WHICH ROOT MEANS ";A$(X);   
390 INPUT W$   
400 IF W$ = A$(X-1) THEN 440  
410 PRINT "YOU MISSED THAT ONE, ";N$;". THE RIGHT ANSWER IS ";A$(X-1);"."  
420 PRINT  
430 GOTO 470  
440 PRINT "THAT IS RIGHT." 
450 PRINT  
460 H= H+10
470 IF Z = 1 THEN 580 
480 A$(X)=A$(2*Z)  
490 A$(X-1) = A$(2*Z-1)
500 Z=Z-1
510 GOTO 370 
580 IF H=200 THEN 620:
590 J$=STR$(H):
600 PRINT "YOUR SCORE WAS ";J$;", ";N$;".":
610 STOP:  
620 PRINT N$;", YOU DID THIS WITHOUT ONE MISTAKE. CONGRATULATIONS.":   
630 END:   
