5 REM *** WRITTEN BY TOM KARZES, CURTIS JR HS, SUDBURY, MA
6 REM *** MODIFIED BY DAVE AHL, DIGITAL
10 PRINT "YOU ARE IN A LARGE, NEW GOVERNMENT BUILDING WITH 1,000,000"
20 PRINT "ROOMS IN IT.  THE BUILDING IS 100 ROOMS LONG (0-99), 100"
30 PRINT "ROOMS WIDE (0-99), AND 100 FLOORS HIGH (0-99).":PRINT 
40 PRINT "A MAD BOMBER HAS HIDDEN A BOMB IN ONE OF THE ROOMS AND"
50 PRINT "HAS JUST PHONED A THREAT THAT THE BOMB IS SET TO GO"
60 PRINT "OFF IN 200 SECONDS.  FORTUNATELY, YOU HAPPEN TO HAVE A BOMB-"
70 PRINT "TRACKER THAT SENDS OUT SIGNALS THAT GET STRONGER AS YOU"
80 PRINT "GET CLOSER TO THE BOMB.  YOU ARE STARTING IN ROOM 0,0,0"
90 PRINT "AND IT TAKES 10 SECONDS TO MOVE TO ANY OTHER ROOM.":PRINT 
100 RANDOMIZE TIMER:A=INT(100*RND):B=INT(100*RND):C=INT(100*RND)
110 IF A=0 AND B=0 AND C=0 THEN 100
120 P1=A/100+B+C*100:D=0:E=0:F=0:G=0:P=0
125 PRINT "SIGNAL","CURRENT ROOM","SEC. INTO","COORDINATES FOR"
130 PRINT "STRENGTH","L , W , H","MISSION","SEARCH (L,W,H)"
132 B$=" ####.##      ##  ##  ##     ###           "
135 PRINT USING B$;10000-ABS(P1-P),D,E,F,G;
140 INPUT D,E,F:G=G+10:P=D/100+E+F*100
142 IF P=P1 THEN 170
145 IF G=200 THEN GOTO 150 ELSE GOTO 180
150 PRINT "BOOOOOOOMMM!!!":PRINT "YOU BLEW IT.  THE BUILDING BLEW UP."
152     PRINT "The bomb coordinates were:";A;",";B;",";C
155 PRINT :INPUT "WANT TO PLAY AGAIN (YES OR NO)";A$
160 IF A$="NO" THEN GOTO 999 ELSE PRINT :PRINT :GOTO 100
170 PRINT "BOMB DEACTIVATED AT";G;"SECONDS!!!":PRINT :GOTO 155
180 IF D>99 OR D<0 OR E>99 OR E<0 THEN 200
190 IF F>99 THEN GOTO 220
195 IF F<0 THEN GOTO 230 ELSE GOTO 135
200 PRINT "YOU WALKED OUT A WINDOW ON THE";
201 IF F<4 THEN 240
205 PRINT  F;"TH FLOOR!!!"
210 PRINT "YOU WERE KILLED AND";200-G;"SECONDS LATER THE BUILDING"
215 PRINT "BLEW UP!!!":PRINT :GOTO 155
220 PRINT "YOU ARE NOW";F*9;"FEET IN THE AIR!!!":GOTO 210
230 PRINT "YOU ARE NOW -";F*9;"FEET UNDERGROUND!!!":GOTO 210
240 ON F GOTO 250,260,270
250 PRINT " 1ST FLOOR!!!":GOTO 210
260 PRINT " 2ND FLOOR!!!":GOTO 210
270 PRINT " 3RD FLOOR!!!":GOTO 210
999 END
