	5 RANDOMIZE TIMER
10 PRINT TAB(34);"BUG":PRINT
20 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
30 PRINT:PRINT:PRINT
40 REM
50 A=0: B=0: H=0: L=0: N=0: P=0: Q=0: R=0: S=0: T=0: U=0: V=0: Y=0
60 PRINT "THE GAME BUG IS LIKE THE GAME COOTI."
70 PRINT "I HOPE YOU ENJOY THIS GAME."
80 PRINT
90 PRINT "DO YOU WANT INSTRUCTIONS";
100 INPUT Z$
110 IF LEFT$(Z$,1)="N" OR LEFT$(Z$,1)="n" THEN 300
120 PRINT "   The object of BUG is to finish your Bug before I finish"
130 PRINT "mine. Each number stands for a part of the bug body."
140 PRINT "I will roll the die for you and tell you what the number"
150 PRINT "stands for, and if you can get the part I will give it"
160 PRINT "to you. The same will happen on my turn."
170 PRINT
200 PRINT "   The numbers stand for parts as follows:":PRINT
210 PRINT "NUMBER","PART","NUMBER OF PART NEEDED"
215 PRINT "------","----","----------------------"
220 PRINT TAB(3);"1","BODY",TAB(38);"1"
230 PRINT TAB(3);"2","NECK",TAB(38);"1"
240 PRINT TAB(3);"3","HEAD",TAB(38);"1"
250 PRINT TAB(3);"4","FEELERS",TAB(38);"2"
260 PRINT TAB(3);"5","TAIL",TAB(38);"1"
270 PRINT TAB(3);"6","LEGS",TAB(38);"6"
280 PRINT
290 LINE INPUT "Enter 'RETURN' to start the game.";RR$:cls
300 IF Y>0 THEN 1750
310 Z=INT(6*RND(1)+1)
320 C=1
330 PRINT:PRINT "YOU ROLLED A";Z;CHR$(8);"."
340 ON Z GOTO 350,430,540,650,760,870
350 PRINT "1=BODY"
360 IF B=1 THEN 410
370 PRINT "YOU NOW HAVE A BODY."
380 B=1
390 C=0
400 GOTO 970
410 PRINT "YOU DO NOT NEED A BODY."
420 GOTO 970
430 PRINT "2=NECK"
440 IF N=1 THEN 500
450 IF B=0 THEN 520
460 PRINT "YOU NOW HAVE A NECK."
470 N=1
480 C=0
490 GOTO 970
500 PRINT "YOU DO NOT NEED A NECK."
510 GOTO 970
520 PRINT "YOU DO NOT HAVE A BODY."
530 GOTO 970
540 PRINT "3=HEAD"
550 IF N=0 THEN 610
560 IF H=1 THEN 630
570 PRINT "YOU NEEDED A HEAD."
580 H=1
590 C=0
600 GOTO 970
610 PRINT "YOU DO NOT HAVE A NECK."
620 GOTO 970
630 PRINT "YOU HAVE A HEAD."
640 GOTO 970
650 PRINT "4=FEELERS"
660 IF H=0 THEN 740
670 IF A=2 THEN 720
680 PRINT "I NOW GIVE YOU A FEELER."
690 A=A+1
700 C=0
710 GOTO 970
720 PRINT "YOU HAVE TWO FEELERS ALREADY."
730 GOTO 970
740 PRINT "YOU DO NOT HAVE A HEAD."
750 GOTO 970
760 PRINT "5=TAIL"
770 IF B=0 THEN 830
780 IF T=1 THEN 850
790 PRINT "I NOW GIVE YOU A TAIL."
800 T=T+1
810 C=0
820 GOTO 970
830 PRINT "YOU DO NOT HAVE A BODY."
840 GOTO 970
850 PRINT "YOU ALREADY HAVE A TAIL."
860 GOTO 970
870 PRINT "6=LEG"
880 IF L=6 THEN 940
890 IF B=0 THEN 960
900 L=L+1
910 C=0
920 PRINT "YOU NOW HAVE";L;"LEGS."
930 GOTO 970
940 PRINT "YOU HAVE 6 FEET ALREADY."
950 GOTO 970
960 PRINT "YOU DO NOT HAVE A BODY."
970 X=INT(6*RND(1)+1)
971 PRINT
975 FOR DELAY=1 TO 2000:NEXT DELAY
980 PRINT "I ROLLED A";X;CHR$(8);"."
990 ON X GOTO 1000,1080,1190,1300,1410,1520
1000 PRINT "1=BODY"
1010 IF P=1 THEN 1060
1020 PRINT "I NOW HAVE A BODY."
1030 C=0
1040 P=1
1050 GOTO 1630
1060 PRINT "I DO NOT NEED A BODY."
1070 GOTO 1630
1080 PRINT "2=NECK"
1090 IF Q=1 THEN 1150
1100 IF P=0 THEN 1170
1110 PRINT "I NOW HAVE A NECK."
1120 Q=1
1130 C=0
1140 GOTO 1630
1150 PRINT "I DO NOT NEED A NECK."
1160 GOTO 1630
1170 PRINT "I DO NOT HAVE A BODY."
1180 GOTO 1630
1190 PRINT "3=HEAD"
1200 IF Q=0 THEN 1260
1210 IF R=1 THEN 1280
1220 PRINT "I NEEDED A HEAD."
1230 R=1
1240 C=0
1250 GOTO 1630
1260 PRINT "I DO NOT HAVE A NECK."
1270 GOTO 1630
1280 PRINT "I DO NOT NEED A HEAD."
1290 GOTO 1630
1300 PRINT "4=FEELERS"
1310 IF R=0 THEN 1390
1320 IF S=2 THEN 1370
1330 PRINT "I GET A FEELER."
1340 S=S+1
1350 C=0
1360 GOTO 1630
1370 PRINT "I HAVE 2 FEELERS ALREADY."
1380 GOTO 1630
1390 PRINT "I DO NOT HAVE A HEAD."
1400 GOTO 1630
1410 PRINT "5=TAIL"
1420 IF P=0 THEN 1480
1430 IF U=1 THEN 1500
1440 PRINT "I NOW HAVE A TAIL."
1450 U=1
1460 C=0
1470 GOTO 1630
1480 PRINT "I DO NOT HAVE A BODY."
1490 GOTO 1630
1500 PRINT "I DO NOT NEED A TAIL."
1510 GOTO 1630
1520 PRINT "6=LEGS"
1530 IF V=6 THEN 1590
1540 IF P=0 THEN 1610
1550 V=V+1
1560 C=0
1570 PRINT "I NOW HAVE";V;"LEGS."
1580 GOTO 1630
1590 PRINT,"I HAVE 6 FEET."
1600 GOTO 1630
1610 PRINT "I DO NOT HAVE A BODY."
1620 GOTO 1630
1630 PRINT:FOR DELAY=1 TO 2000:NEXT:IF A=2 AND T=1 AND L=6 THEN 1650
1640 GOTO 1670
1650 PRINT "YOUR BUG IS FINISHED."
1660 Y=Y+1
1670 IF S=2 AND P=1 AND V=6 THEN 1690
1680 GOTO 1710
1690 PRINT "MY BUG IS FINISHED."
1700 Y=Y+2
1710 IF C=1 THEN 300
1720 INPUT "DO YOU WANT THE DESCRIPTIONS?";D$
1730 IF LEFT$(D$,1)="Y" THEN 1770
1740 GOTO 300
1750 INPUT "PLAY AGAIN?";GG$
1760 IF LEFT$(GG$,1)="Y" THEN CLEAR:GOTO 300 ELSE END
1770 IF B=0 THEN PRINT "YOU HAVE NO BODY SO YOU CANNOT HAVE ANY OTHER BODY PARTS.":GOTO 1790
1780 PRINT "YOU HAVE"B"BODY,"N"NECK,"H"HEAD,"A"FEELERS,"T"TAIL AND"L"LEGS."
1790 IF P=0 THEN PRINT "I HAVE NO BODY SO I CANNOT HAVE ANY OTHER PARTS.":GOTO 1810
1800 PRINT "I HAVE"P"BODY,"Q"NECK,"R"HEAD,"S"FEELERS,"U"TAIL AND"V"LEGS."
1810 LINE INPUT "PRESS RETURN TO CONTINUE.";BB$
1820 GOTO 300
