10      RANDOMIZE TIMER
15      PRINT "HI.  TO STOP, TYPE 9999 FOR YOUR ANSWER."
20      PRINT "WHAT IS YOUR GRADE LEVEL";
30      INPUT G1
40      G2=G1-.5+RND
50      R=INT(2*1.73*G2^4)
60      A=INT(100*G2*RND)
70      IF A>R THEN 60
80      B=R-A
100     PRINT
102        FOR I=1 TO LEN(STR$(B))-LEN(STR$(A))+3
104        PRINT " ";
106        NEXT
108        PRINT A
120     PRINT " + ";B
140     R=A+B
200     PRINT "_______"
210     INPUT G
220     IF G=R THEN 310
225     IF G=9999 THEN 500
230     W=W+1
240     IF W>1 THEN 270
250     PRINT "WRONG, TRY AGAIN."
260     GOTO 100
270     PRINT "YOU MISSED THAT ONE TWICE."
280     PRINT "THE CORRECT ANSWER IS ";R
285     W=0
290     IF G2>G1 THEN 400
300     GOTO 350
310     W=0
320     PRINT "CORRECT !!!"
330     IF G2>G1 THEN 400
350     G1=.9*G1+.1*SQR(SQR(R/2/1.73))
400     PRINT: PRINT "HERE'S ANOTHER..."
410     GOTO 40
500     PRINT "OKAY.  SO LONG.  HOPE YOU ENJOYED IT."
510     PRINT "YOUR GRADE LEVEL IS NOW ";G1
999     END
