100 P=5000
110 PRINT "THIS PROGRAM IS DESIGNED TO SIMULATE THE FRENCH GAMBLING" 
120 DIM G(10)
130 P=5000   
140 PRINT "GAME ROULETTE."   
150 PRINT "DO YOU WISH TO SEE A DESCRIPTION OF THE RULES"
160 INPUT A$ 
170 IF A$="NO" THEN 450  
180 PRINT "YOU BEGIN WITH $5,000 AND MAY BET AS MUCH AS YOU LIKE UNTIL"  
190 PRINT "YOU HAVE EITHER WON $100,000 OR YOU GO BROKE, WHICH EVER" 
200 PRINT "COMES FIRST.  THE BETTING IS DONE ON A BOARD OR CLOTH"
210 PRINT "SUCH AS APPEARS BELOW.  HALF THE NUMBERS ARE RED AND HALF"
220 PRINT "ARE BLACK EXCEPT ZERO WHICH IS COLORLESS.  BETTING COM-"  
230 PRINT "BINATIONS AND ODDS ON THEM ARE AS FOLLOWS:"   
240 PRINT
250 PRINT "**************************************************************"   
260 PRINT "          BET                          BANK PAYS" 
270 PRINT "     -------------         --------------------------------"  
280 PRINT " 1. RED OR BLACK             EVEN MONEY (AMOUNT OF BET)"  
290 PRINT " 2. EVEN OR ODD              EVEN MONEY"  
300 PRINT " 3. HIGH OR LOW             EVEN MONEY"  
310 PRINT " 4. COLUMN 1,2,OR 3          2 TO 1"  
320 PRINT " 5. DOZEN (LOW,MIDDLE,HIGH)  2 TO 1"  
330 PRINT " 6. SINGLE NUMBERS 0-36      36 TO 1" 
340 PRINT " 7. TWO NUMBERS(ADJACENT)    17 TO 1" 
350 PRINT " 8. THREE NUMBERS ACROSS    11 TO 1" 
360 PRINT " 9. FOUR NUMBERS (SQUARE)    8 TO 1"  
370 PRINT "10. SIX NUMBERS(RECTANGLE)   5 TO 1"  
380 PRINT "**************************************************************"   
390 PRINT   
415 PRINT "PRESS ANY KEY TO CONTINUE.":I$=INPUT$(1)
420 CLS:PRINT "WHEN ASKED TO PLACE YOUR BET, DO SO BY FIRST INPUTTING"   
430 PRINT "THE AMOUNT OF THE BET (SMALLEST BET =$1.00) AND THE" 
440 PRINT "NUMBER OF THE TYPE OF BET DESIRED FROM THE TABLE ABOVE"  
450 PRINT "HERE IS THE ROULETTE LAYOUT:"
460 PRINT "              ***********************"   
470 PRINT "              *         0           *"   
480 PRINT "              *   1     2      3    *"   
490 PRINT "              *   4     5      6    *"   
500 PRINT "              *   7     8      9    *"   
510 PRINT "              *  10    11     12    *"   
520 PRINT "              *  13    14     15    *"   
530 PRINT "              *  16    17     18    *"   
540 PRINT "              *  19    20     21    *"   
550 PRINT "              *  22    23     24    *"   
560 PRINT "              *  25    26     27    *"   
570 PRINT "              *  28    29     30    *"   
580 PRINT "              *  31    32     33    *"   
590 PRINT "              *  34    35     36    *"   
600 PRINT "              ***********************"   
610 PRINT "              ***********************"   
620 PRINT "THE ROULETTE WHEEL IS SPINNING-ROUND AND ROUND IT"   
630 PRINT "GOES, WHERE SHE STOPS NOBODY KNOWS." 
640 X=0 
650 Y=INT(37*RND(1))
660 PRINT "FAITES VOS JEUX MESSIEUR (PLACE YOUR BETS GENTLEMEN)"
670 INPUT B,C   
680 IF C=2 THEN 890 
690 IF C=3 THEN 990 
700 IF C=4 THEN 1090 
710 IF C=5 THEN 1280 
720 IF C=6 THEN 1430 
730 IF C=7 THEN 1490 
740 IF C=8 THEN 1560
750 IF C=9 THEN 1640
760 IF C=10 THEN 1730   
770 E=1 
780 PRINT "WHICH COLOR DO YOU WANT TO BET ON"   
790 INPUT Z$
800 IF Y=0 THEN 1880
810 IF Y<19 THEN 860
820 PRINT " THE NUMBER IS BLACK"
830 IF LEFT$(Z$,1)="B" THEN 1820 
840 GOTO 1880  
850 PRINT   
860 PRINT "THE NUMBER IS RED"   
870 IF LEFT$(Z$,1)="R" THEN 1820   
880 GOTO 1880  
890 E=1 
900 PRINT "WHICH DO YOU WANT TO BET ON, ODD OR EVEN"
910 INPUT D$
920 PRINT "THE NUMBER IS"Y  
930 D1=Y/2  
940 IF D1=INT(Y/2) THEN 970 
950 IF LEFT$(D$,1)="O" THEN 1820   
960 GOTO 1880  
970 IF LEFT$(D$,1)="E" THEN 1820  
980 GOTO 1880  
990 E=1 
1000 PRINT "DO YOU BET HIGH (19-36) OR LOW (1-18)"   
1010 INPUT H$
1020 PRINT "THE NUMBER IS"Y  
1030 IF Y=0 THEN 1880
1040 IF Y>18 THEN 1070
1050 IF LEFT$(H$,1)="L" THEN 1820   
1060 GOTO 1880  
1070 IF LEFT$(H$,1)="H" THEN 1820  
1080 GOTO 1880  
1090 E=2 
1100 PRINT "WHICH COLUMN DO YOU CHOOSE, 1,2,OR 3"
1110 INPUT F 
1120 PRINT "THE NUMBER IS"Y  
1130 IF Y=0 THEN 1880
1140 IF F=2 THEN 1200 
1150 IF F=3 THEN 1240 
1160 FOR F1=1 TO 34 STEP 3 
1170 IF F1=Y THEN 1820   
1180 NEXT F1 
1190 GOTO 1880  
1200 FOR F1=2 TO 35 STEP 3 
1210 IF F1=Y THEN 1820   
1220 NEXT F1 
1230 GOTO 1880  
1240 FOR F1=3 TO 36 STEP 3 
1250 IF F1=Y THEN 1820   
1260 NEXT F1 
1270 GOTO 1880  
1280 E=2 
1290 PRINT "WHICH DOZEN NUMBERS DO YOU CHOOSE, LOW (1-12), MIDDLE"   
1300 PRINT "(13-24), OR HIGH (25-36)"
1310 INPUT I$
1320 PRINT " THE NUMBER IS "Y
1330 IF Y=0 THEN 1880
1340 IF LEFT$(I$,1)="M" THEN 1380 
1350 IF LEFT$(I$,1)="H" THEN 1410   
1360 IF Y<13 THEN 1820   
1370 GOTO 1880  
1380 IF Y>25 THEN 1880   
1390 IF Y<13 THEN 1880   
1400 GOTO 1820  
1410 IF Y>24 THEN 1820   
1420 GOTO 1880  
1430 E=36
1440 PRINT "OH OH, A LONG SHOT....PICK YOUR NUMBER." 
1450 INPUT G 
1460 PRINT "AND THE NUMBER COMES UP --------------------------"Y 
1470 IF G=Y THEN 1820
1480 GOTO 1880  
1490 E=17
1500 PRINT "WHAT TWO ADJACENT NUMBERS ARE YOU BETTING ON"
1510 INPUT G1,G2 
1520 PRINT " AND THIS TIME THE NUMBER COMES UP-----------------"Y
1530 IF G1=Y THEN 1820   
1540 IF G2=Y THEN 1820   
1550 GOTO 1880  
1560 E=11   
1570 PRINT "WHAT THREE NUMBERS(RUNNING ACROSS THE BOARD) DO YOU WANT"  
1580 INPUT G1,G2,G3 
1590 PRINT "AND THE NUMBER IS ::::::::::::::::::::::::::"Y  
1600 IF G1=Y THEN 1820  
1610 IF G2=Y THEN 1820  
1620 IF G3=Y THEN 1820  
1630 GOTO 1880 
1640 E=8
1650 PRINT "WHAT FOUR NUMBERS( IN A SQUARE ) DO YOU WANT"   
1660 INPUT G(1),G(2),G(3),G(4)  
1670 PRINT "THE MARBLE FALLS AND BOUNCES AND BOUNCES AND, AND"  
1680 PRINT "THE NUMBER COMES UP"Y   
1690 FOR I=1 TO 4 
1700 IF G(I)=Y THEN 1820
1710 NEXT I 
1720 GOTO 1880 
1730 E=5
1740 PRINT "WHAT SIX NUMBERS (IN A RECTANGLE OOO THE BOARD) DO YOU "
1750 PRINT "WANT TO BET ON" 
1760 INPUT G(1),G(2),G(3),G(4),G(5),G(6)
1770 PRINT "WELL, THE NUMBER CAME UP"Y  
1780 FOR I=1 TO 6 
1790 IF G(I)=Y THEN 1820
1800 NEXT I 
1810 GOTO 1880 
1820 PRINT " *****A WINNER*****"
1830 PRINT "YOU WIN $"E*B   
1840 P=P+(E*B)  
1850 PRINT "YOUR PURSE NOW TOTALS $"P   
1860 IF P>100000! THEN 1930  
1870 GOTO 650  
1880 PRINT " *****YOU LOSE*****"
1890 P=P-B  
1900 PRINT "YOUR PURSE NOW TOTALS $"P   
1910 IF P>0 THEN 650
1920 IF P=<0 THEN 1950  
1930 PRINT "END OF GAME YOU BROKE THE HOUSE"
1940 GOTO 1960 
1950 PRINT "YOU'RE BROKE!!!!!"   
1960 END
