10 RANDOMIZE TIMER 
21 PRINT"Adventure on the Red Planet":PRINT"from MaVeRiCk SoFtWaRe":PRINT"copyright <c> 1988"
25 PRINT"BARSOOM is released under the Shareware concept. Feel free to copy or distributethe Program but if you use it PLEASE    send a contribution of $10 to :
26 PRINT"         Maverick Software                       2/26 Lewisham Rd.                       Prahran VIC 3181                        Ph (03) 529 7440
50 DEFINT G,H,F,I,L,S,N,D,T,X,Y,Z,P,J,R,C
100 CLEAR ,,2500
101 X=50:Y=13:Z=10:DIM A$(X),O1$(Y),M1$(Z),O2$(Y),M2$(Z),T(4,X),V$(34),C(34),P(Y),N(Z),E$(Y),LE$(4)
102 DATA in the City of Warhoon,in the City of Warhoon,v,p,in the Temple of Issus,in the deserted City of Thark,in the deserted city of Thark,v,l,v,in the city of Torquas
103 DATA d,v,v,v,d,d,at the mouth of the River Iss,v,v,d,in the City of Ptarth,r,in the Village of Dusar,on the Toonoolian Marshes,d,d,r,p,In the ghost City of Horz,d,d,on a bridge over the River Iss,p,p,d,at the Gate of Jeddaks,r,p,p,l
104 DATA in the Twin Cities of Helium,r,l,p,in the Temple of Reward,on the Aisle of Hope,at the source of the Iss,p,in the city of Zodanga
106 DATA a bejewelled longsword,LONGSWORD,a two-edged shortsword,SWORD,a radium pistol,PISTOL,a redwood spear,SPEAR,a sharp hunting knife,KNIFE,an empty drinking flask,FLASK,poisonous water,WATER,a golden amulet,AMULET,a silver medallion,MEDALLION
109 DATA an ancient key,KEY,six locked doors,DOORS,juicy wild berries,BERRIES,juicy wild berries,BERRIES
110 DATA a ferocious calot,CALOT,1,an enormous hungry banth,BANTH,11,a vicious apt,APT,31,a bloodsucking plantman,PLANTMAN,15,a homicidal humanoid,HUMANOID,45,a Thurian pirate,PIRATE,9,Matai Shang...Holy Thern,THERN,10
111 DATA ,6,2,,,,,1,,8,4,,,9,,3,,10,,,1,,7,,,12,,6,3,13,,,41,9,44,44,5,15,,,,,12,,7,17,,11,8,18,14,,,19,,13,10,20,,,,21,17,,12,,,16,13,23,,,14,,20,,15,,,19,16,26,,,,27,,,,28,24,,,29,25,23,,,,24,21,31,27,,22,32,,26,23,38,,,24,34,,,,35,,
113 DATA 26,36,32,,27,,33,31,,,34,32,29,39,35,33,30,,,34,31,41,37,,,,,36,18,43,,,34,,40,,,45,,39,41,41,36,41,37,47,,,38,48,,,41,44,45,41,40,50,,44,,,47,,42,,,,43,,49,,,2,50,48,45,,,49
114 DATA TAKE,1,GET,1,DROP,2,THROW,2,GO,3,RUN,3,LOOK,4,EXAMINE,4,READ,4,INV,5,QUIT,6,KILL,7,HIT,7,DRINK,8,OPEN,9,UNLOCK,9,GIVE,10,PAY,10,FREE,11,RESCUE,11,LEVEL,12,SCORE,12,RATING,12,FFFF,13,SSSS,13,PPPP,13,CCCC,13,EAT,14,FIND,15,SWIM,16,CLIMB,17,BREAK,18
115 FOR C=1 TO X:READ A$(C):IF A$(C)="d" THEN A$(C)="in the desert" ELSE IF A$(C)="p" THEN A$(C)="on the open plains" ELSE IF A$(C)="r" THEN A$(C)="beside the River Iss" ELSE IF A$(C)="v" THEN A$(C)="in the Valley Dor"
116 IF A$(C)="l" THEN A$(C)="in an ancient labyrinth"
117 NEXT:FOR C=1 TO Y:READ O1$(C),O2$(C):NEXT:O1$(0)="the Princess...Dejah Thoris":O2$(0)="LADY":FOR C=1 TO 13
118 R=INT(2*RND+1)+5*INT(RND*10):P(C)=R:NEXT:P(1)=46:P(2)=2:P(7)=25:P(11)=5:P(10)=37:P(5)=2+INT(RND*3+1)+5*INT(RND*10)
119 FOR C=1 TO Z-3:READ M1$(C),M2$(C),N(C):NEXT:FOR C=8 TO 10:R=1+INT(RND*50):M1$(C)="a huge hungry sith":M2$(C)="SITH":N(C)=R:NEXT:FOR C=1 TO X:READ T(1,C),T(2,C),T(3,C),T(4,C):NEXT:T$(1)="NORTH":T$(2)="SOUTH":T$(3)="EAST":T$(4)="WEST":N=34
120 FOR C=1 TO N:READ V$(C),C(C):NEXT:V$(24)=CHR$(70)+CHR$(85)+CHR$(67)+CHR$(75):V$(25)=CHR$(83)+CHR$(72)+CHR$(73)+CHR$(84):V$(26)=CHR$(80)+CHR$(73)+STRING$(2,83):V$(27)=CHR$(67)+CHR$(85)+CHR$(78)+CHR$(84)
121 DATA SAVE,19,LOAD,20,NEGATIVE,LEVEL 1,LEVEL 2,LEVEL 3
122 FOR C=1 TO 4:READ LE$(C):NEXT:L=1
131 E$(1)="BM200,84H4U30L4G2L2H2U4E2R2F2R6U2NR4U2NR4U2NR4U2NR4H2U2E2R4F2D2G2D8R6E2R2F2D4G2L2H2L4D30G4U30BU2"
132 E$(2)="BM150,95BU4U4R4U4R2D4R20F2G2L20D4L2U4NU4L2NU4L2BR5BU"
133 E$(3)="BM180,95U2E1U12R2F2R10URDR2URD6LUL6NL4D2G2L2BU4NF2D6F1D2L8BE4"
134 E$(4)="BM80,95BU4R30F2R4E3H3L4G2L30D2BE"
135 E$(5)="BM122,95BU4R4FR16E2H2L16GL4D2BE"
136 E$(6)="BM200,95U8E6U2L2U2R8D2L2D2F6R6D8L6BU2R4U4L4D4BD2L16BE2"
137 E$(7)=""
138 E$(8)="BM60,96H4E12F4G12BR8H12E4F12G4H2NE4H8NE4BD4NF4E8F4E2D8G4L8H4U8E4R8"
139 E$(9)="BM40,97U8R8D8L8BE2U4R4D4L4BU6R2M-5,-8M+5,-3M+5,3M-5,8BD"
140 E$(10)="BM10,95BU4R4E4R6D2R2U2R2D2R2U2R2D4R2U8L16H4L4G4D4F4BU3H2U2E2R2F2D2G2L2BD"
141 E$(11)=""
142 E$(12)="H2E2F2NG2F4H2E2F2NG2F4U4H2E2F2G2H6H2E2F2NG2BU4":E$(12)=E$(12)+E$(12)
143 E$(13)="BM280,95"+E$(12)+"BD4"
144 E$(12)=E$(13)
200 '
202 VV=FRE(0):VV=FRE(A$):IF A$(L)=TD$ THEN 210
204 IF L>25 THEN 205 ELSE ON L GOSUB 420,420,422,446,424,428,428,422,429,422,430,432,422,422,422,432,432,438,422,422,432,440,438,436,442
205 IF L>25 THEN ON L-25 GOSUB 432,432,438,446,434,432,432,448,446,446,432,456,438,446,446,429,462,438,429,446,470,472,438,446,444
206 IF L=5 THEN  GOSUB 426 ELSE IF L=37 THEN GOSUB 458 ELSE IF L=42 THEN  GOSUB 464 ELSE IF L=47 THEN GOSUB 478
210 PRINT"You are "A$(L)".":PRINT"Paths go:"STRING$(30,32);:T(3,32)=0:T(4,34)=0:FOR C=1 TO 4:IF T(C,L)>0 THEN PRINT T$(C)", ";
212 NEXT:PRINT
214 PRINT STRING$(80,32);:VI=0:PRINT"You see :";:R=1+INT(RND*20):IF R=8 THEN N(1+INT(RND*6))=L
215 IF L=47 THEN PRINT"GUARD,";:VI=VI+1
216 FOR C=1 TO 10:IF N(C)=L THEN PRINT M2$(C)",";:VI=VI+1
218 NEXT :FOR C=0 TO Y:IF P(C)=L THEN PRINT O2$(C)",";:VI=VI+1
220 NEXT :IF L=32 OR L=34 THEN GOSUB 450:VI=VI+1
222 IF VI=0 THEN PRINT"Nothing unusual."
224 FOR C=0 TO 13:IF P(C)=L THEN GOSUB 3000:GOSUB 482
225 NEXT:PRINT
226 A0$="":GOSUB 402:PRINT:FOR C=1 TO 4:IF A0$=T$(C) OR A0$=LEFT$(T$(C),1) THEN A0$=V$(5)+" "+T$(C) ELSE NEXT
228 FOR C=1 TO 4:IF A0$="RUN "+LEFT$(T$(C),1) THEN A0$="RUN "+T$(C) ELSE NEXT
230 FOR C=1 TO LEN(A0$):IF MID$(A0$,C,1)=" " THEN A1$=LEFT$(A0$,C-1):B0$=MID$(A0$,C+1,LEN(A0$)-C):GOTO 234 ELSE NEXT
232 A1$=A0$:IF A0$="INV" OR A0$="LOOK" OR A0$="QUIT" OR LEFT$(A0$,4)="SCOR" OR LEFT$(A0$,4)="RATI" OR LEFT$(A0$,4)="LEVE" THEN 234 ELSE 236
234 B4$=LEFT$(B0$,4):FOR C=1 TO N:IF V$(C)=A1$ OR LEFT$(V$(C),4)=A1$ THEN A=C(C):GOSUB 270:GOTO 238
235 NEXT
236 PRINT:PRINT "What???":GOTO 268
238 ON A GOTO  240,298,304,342,372,384,280,302,314,324,358,368,600,610,620,630,540,650,1000,2000
240 IF I=3 THEN 246 ELSE GOSUB 252:IF L=46 AND B4$=LEFT$(O2$(1),4) THEN GOSUB 256
242 FOR C=1 TO Y:IF B4$=LEFT$(O2$(C),4) AND P(C)=L THEN GOSUB 250:P(C)=1000:PRINT"O.K...You have the "O2$(C)".":I=I+1:GOSUB 800:TD$="":GOTO 202 ELSE NEXT
244 PRINT "You cannot take that, you fool!":GOTO 268
246 PRINT"You are carrying too much!":GOTO 268
248 PRINT "The "M2$(V)" sat on it.":GOTO 268
250 FOR V=1 TO Z:IF N(V)=L THEN GOSUB 248 ELSE NEXT:RETURN
252 IF B4$="WATE" AND P(6)<>1000 THEN PRINT "Try putting it in something!":GOTO 268 ELSE IF L=25 AND B4$="WATE" AND P(6)=1000 THEN O1$(6)="a full drinking flask":F=1:PRINT "O.K. Your flask is full.":GOTO 268
254 IF B4$="WATE" THEN PRINT"You cannot reach any.":GOTO 268 ELSE RETURN
256 IF D=0 THEN GOSUB 4000:PRINT"You stole the longsword of the Jeddak ofHelium. You did not rescue Dejah Thoris so you will suffer an agonising DEATH!":FOR T=1 TO 2000:NEXT:GOSUB 4000:PRINT"You're dead!":GOTO 498 ELSE 262
262 IF D=1 THEN GOSUB 4000:PRINT"Because you rescued Dejah Thoris, her   father Tardos Mors, Jeddak of Helium","allows you to claim the famous longswordthat proclaims you ...","*** WARLORD OF BARSOOM ***":SC=SC+1000 ELSE 266
263 FOR T=1 TO 2000:NEXT:GOSUB 4000:PRINT:PRINT"*** CONGRATULATIONS ***":GOTO 498
266 RETURN
268 GOSUB 800:GOTO 226
269 GOSUB 484:GOTO 214
270 IF A<>3 THEN RETURN ELSE FOR X=1 TO Z:IF N(X)<>L THEN NEXT :RETURN
272 IF LEFT$(B0$,3)="TO " THEN B0$=RIGHT$(B0$,LEN(B0$)-3):B4$=LEFT$(B0$,4)
274 IF B4$=LEFT$(M2$(X),4) THEN PRINT"That could be fatal!":GOTO 268
276 IF A1$<>"RUN" THEN PRINT"The "M2$(X)" catches you.":GOTO 292 ELSE SC=SC-1:PRINT"Coward! Lose one point."
278 GOSUB 800:GOTO 304
280 FOR C=1 TO 5:IF P(C)=1000 THEN GOSUB 700 ELSE NEXT:PRINT"You don't have a weapon.":GOTO 268
282 RR=1+INT(RND*20):IF RR=8 THEN 292 ELSE FOR C=1 TO Z:GOSUB 288:IF B4$=LEFT$(M2$(C),4) AND N(C)=L THEN N(C)=1+INT(RND*50):PRINT"You killed "M1$(C)".":SC=SC+1:GOSUB 286 ELSE 285
284 PRINT"Bonus:1 point.":GOSUB 294:GOSUB 800:GOSUB 484:GOTO 214
285 NEXT:IF B4$="GUAR" THEN PRINT"He scoffs at your attack.":GOTO 268 ELSE PRINT"You cannot kill a "B0$".":GOTO 268
286 IF MS=0 THEN RETURN ELSE IF M2$(7)="THERN" AND L=10 THEN M1$(7)="a fanatical thern":N(7)=15:MS=1:RETURN ELSE RETURN
288 IF MS=0 AND (B4$="THER" OR B4$="MATA") THEN PRINT"You cannot harm him that way.":GOTO 268
290 RETURN
292 PRINT:PRINT"Too bad ... you are a bit dead!":GOTO 498
294 R=1+INT(RND*10):IF R=9 THEN P(W)=0 ELSE IF R<3 THEN P(W)=1+INT(RND*50) ELSE  RETURN
296 PRINT"Your "O2$(W)" broke!":I=I-1::GOSUB 800:GOSUB 484:GOTO 214
298 FOR C=1 TO Y:IF B4$=LEFT$(O2$(C),4) AND P(C)=1000 THEN P(C)=L:I=I-1:PRINT"OK - You dropped your "O2$(C)".":GOTO 268 ELSE NEXT
300 PRINT"Idiot! You don't have one.":GOTO 268
302 IF O1$(6)="a full drinking flask" AND B4$="WATE" THEN PRINT"That water was poisonous!":GOTO 292 ELSE PRINT "You don't have any.":GOTO 268
304 IF LEFT$(B0$,3)="TO " THEN B0$=RIGHT$(B0$,LEN(B0$)-3):GOTO 304 ELSE FOR C=1 TO 4:IF B0$=T$(C) OR B0$=LEFT$(T$(C),1) THEN DR=C:GOTO 308
306 NEXT :PRINT "You cannot go there.":GOTO 268
308 IF LEFT$(B0$,1)="N" AND L=10 AND MS=0 THEN PRINT "You cannot pass the Holy Thern.":GOTO 268 ELSE IF T(DR,L)>0 THEN TD$=A$(L):PRINT"OK - Heading "T$(C)"...":GOTO 312 ELSE PRINT "You cannot go "B0$"."
310 IF (B0$=T$(3) AND L=32) OR (B0$=T$(4) AND SC>4 AND D=0 AND L=34) THEN PRINT "Only Level 2 warriors may cross.":GOTO 268 ELSE  IF L=34 AND B0$=T$(4) AND (D=1 OR SC<5) THEN PRINT "Only Level 3 warriors may cross.":GOTO 268 ELSE 268
312 GOSUB 800:FOR C=0 TO 13:IF P(C)=L THEN TD$="X" ELSE NEXT
313 L=T(DR,L):GOTO 202
314 IF L=37 AND B4$="GATE" THEN J=1:T(2,37)=42:T(4,37)=36:GOTO 226
318 IF L=5 AND P(10)<>1000 THEN PRINT "It is locked ... You have no key!":GOTO 268
320 IF L=5 AND B4$="DOOR" AND P(11)<>0 THEN PRINT"OK-A door opens.":P(11)=0:P(0)=5:GOTO 268 ELSE IF L=5 AND B4$="DOOR" THEN PRINT"The other doors won't open." ELSE IF B4$="DOOR" THEN PRINT"I see no door." ELSE PRINT"It won't open!"
322 GOTO 268
324 IF L=47 AND G=0 THEN GOSUB 660
325 IF L=47 AND (B4$="MEDA" OR B4$="AMUL") THEN G=0:GOTO 326 ELSE IF L=10 THEN 330 ELSE PRINT"Whatever for?":G=0:GOTO 268
326 FOR C=1 TO Y:IF B4$=LEFT$(O2$(C),4) AND P(C)=1000 THEN P(C)=0:I=I-1:T(4,47)=46 ELSE NEXT:PRINT"You don't have one.":GOTO 268
328 PRINT"Thanks mate!";:PRINT"In you go...";:GOSUB 484:GOTO 210
330 FOR C=1 TO Y:IF N(7)<>L THEN 340
332 IF L=10 AND MS=0 AND O1$(6)="a full drinking flask" AND P(6)=1000 AND (B4$="WATE" OR B4$="FLAS") THEN PRINT"Matai Shang drinks the water...":FOR T=1 TO 2000:NEXT:PRINT"and dies!":M1$(7)="A fanatical thern":M2$(7)="THERN" ELSE 336
334 MS=1:N(7)=47:O1$(6)="an empty drinking flask":F=0:P(6)=L:GOSUB 800:TD$=A$(L):GOTO 202
336 IF B4$=LEFT$(O2$(C),4) AND P(C)=1000 THEN PRINT "The thern takes the "O2$(C)".":P(C)=0:GOTO 268
338 NEXT
340 PRINT"He does not want it.":GOTO 268
342 IF A0$=A1$ THEN TD$=A$(L):GOTO 202
350 IF B4$=LEFT$(O2$(0),4) AND P(0)=L THEN O2$(0)="DEJAH THORIS":PRINT "You see "O1$(0)".":TD$=A$(L):GOSUB 800:GOTO 202
352 FOR C=1 TO Y:IF B4$=LEFT$(O2$(C),4) AND P(C)=L THEN PRINT "You see "O1$(C)".":GOTO 268 ELSE NEXT
354 FOR C=1 TO Z:IF B4$=LEFT$(M2$(C),4) AND N(C)=L THEN PRINT "You see "M1$(C)".":IF C=7 THEN M2$(7)="MATAI SHANG":TD$=A$(L):GOSUB 800:GOTO 202 ELSE 268 ELSE NEXT
355 IF B4$="GUAR" THEN PRINT "He looks greedy and corrupt!":GOTO 268
356 IF 1+INT(RND*10)<4 THEN PRINT "That looks very, very interesting!":GOTO 268 ELSE PRINT"You see nothing special.":GOTO 268
358 IF B4$<>"LADY" AND B4$<>"DEJA" AND B4$<>"PRIN" THEN PRINT "Whatever for???":GOTO 268 ELSE IF L<>P(0) THEN PRINT "You cannot do that ... yet!":GOTO 268
360 PRINT"With what? ";:A0$="":GOSUB 406:A4$=LEFT$(A0$,4):IF A4$<>LEFT$(O2$(2),4) AND A4$<>LEFT$(O2$(5),4) THEN 366 ELSE FOR C=2 TO 5:IF P(C)=1000 THEN IF A4$=LEFT$(O2$(C),4) THEN 364
362 NEXT :PRINT "You don't have one.":GOTO 268
364 PRINT:PRINT"Dejah Thoris is free!":P(0)=1000:D=1:SC=SC+50:J=0:T(2,37)=0:PRINT"BONUS: 50 points!":GOTO 268
366 PRINT"That will not cut her free!":GOTO 268
368 SC$=STR$(SC):PRINT"SCORE: "SC$"     RATING: ";:IF SC<0 THEN PRINT LE$(1) ELSE IF SC<4 THEN PRINT LE$(2) ELSE IF SC<51 THEN PRINT LE$(3) ELSE PRINT LE$(4)
370 GOTO 268
372 PRINT "You are carrying :":FOR V=1 TO Y
374 IF P(V)=1000 THEN PRINT ,O1$(V)", "
376 IF I=0 THEN PRINT "Absolutely nothing!":GOTO 380
378 NEXT
380 IF P(0)=1000 THEN PRINT ,"*** Dejah Thoris is with you."
382 GOSUB 800:GOTO 268
384 PRINT"OK PIKER ... SEE YOU LATER.":GOTO 498
402 PRINT"What now? ";
404 A0$=""
406 input "",a0$:RETURN
407 IF ASC(I$)>96 AND ASC(I$)<123 THEN I$=CHR$(ASC(I$)-32)
418 GOTO 406
420 B$="04":RETURN
422 B$="13":RETURN
424 B$="14":RETURN
426 IF P(11)=0 THEN  RETURN
428 B$="03":RETURN
429 B$="15":RETURN
430 B$="06":RETURN
432 B$="05":RETURN
434 B$="17":RETURN
436 B$="01":RETURN
438 B$="11":RETURN
440 B$="07":RETURN
442 B$="16":RETURN
444 B$="19":RETURN
446 B$="08":RETURN
448 B$="18":RETURN
450 PRINT" A BRIDGE ";:IF L=32 THEN PRINT "EAST, "; ELSE PRINT "WEST, ";
452 IF SC>3 THEN T(3,32)=33:IF (D=1 AND SC>50) OR (D=0 AND SC>4) THEN T(3,34)=33
454 RETURN
456 B$="09":RETURN
458 '
460 H=0:RETURN
462 B$="10":RETURN
464 IF H=0 THEN QQ=4:K1=94:K2=224 ELSE QQ=-4:K1=216:K2=86
466 FOR T=K1 TO K2 STEP QQ:K1=K1+QQ:NEXT :J=0:T(4,37)=0
468 RETURN
470 B$="12":RETURN
472 B$="02":RETURN
478 IF D=1 THEN PRINT "So you freed the";:PRINT"Princess ...";:PRINT"That does not pay";:PRINT"my bills ...";:PRINT"You cannot go in!";
480 H=1:RETURN
482 IF F=1 AND P(6)=L THEN  RETURN
484 RETURN
486 RETURN
488 RETURN
490 IF TM<10000 THEN RETURN
491 FOR C=1 TO 10
492 IF N(C)=L THEN 494
493 IF C=11 THEN RETURN ELSE 496
494 TM2=0:PRINT:PRINT "The "M2$(C)" attacks ... ";:R=1+INT(RND*30):FOR T=1 TO 3:NEXT:IF R=3 THEN 292 ELSE GOSUB 800:PRINT "           ...and misses!"
496 NEXT: TM=0:GOTO 268
498 PRINT"Your score was:"SC:PRINT:PRINT"PLAY AGAIN [Y/N]? ";
500 I$=INKEY$:IF I$<>"Y" AND I$<>"y" AND I$<>"N" AND I$<>"n" THEN 500 ELSE IF I$="Y" OR I$="y" THEN RUN ELSE CLS:SYSTEM
600 R=1+INT(RND*4):PRINT"Watch your tongue, "V$(23+R)"FACE!":GOTO 268
610 IF B4$=LEFT$(O2$(12),4) AND P(12)=1000 THEN PRINT "Yum, yum, you feel stronger.":P(12)=1+INT(RND*50):I=I-1:SC=SC+1:GOTO 268 ELSE IF B4$=LEFT$(O2$(13),4) AND P(13)=1000 THEN PRINT "They were bad...you lose strength!":I=I-1:SC=SC-1 ELSE 612
611 P(13)=1+INT(RND*50):GOTO 268
612 FOR C=1 TO Y:IF B4$=LEFT$(O2$(C),4) AND P(C)=1000 THEN PRINT "Ouch! You broke a tooth!":GOTO 268 ELSE NEXT :PRINT "You cannot eat what you don't have!":GOTO 268
620 PRINT"Find it yourself!":GOTO 268
630 IF L=18 OR L=23 OR L=25 OR L=28 OR L=38 OR L=43 OR L=48 THEN PRINT "You dive in ... and swim ..." ELSE PRINT "You need water to swim in!":GOTO 268
632 FOR DR=1 TO 9:PRINT"............... and swim ...":FOR T=1 TO 500:NEXT T,DR:PRINT:PRINT"You finally drowned!":GOTO 498
640 PRINT"It's much too high to climb.":GOTO 268
650 PRINT "Good try, but it just won't break!":GOTO 268
660 IF B4$="GUAR" THEN PRINT "What will you give the guard?   ";:G=1:GOTO 268 ELSE IF B4$="MEDA" OR B4$="AMUL" THEN G=1:GOTO 325 ELSE PRINT "Give it to somebody else!":GOTO 268
700 NW=0:FOR C=1 TO 5:IF P(C)=1000 THEN NW=NW+1:W=C
702 NEXT :IF NW=1 THEN RETURN ELSE PRINT "Which weapon? ";:GOSUB 404:A4$=LEFT$(A0$,4):FOR W=1 TO 5:IF A4$<>LEFT$(O2$(W),4) OR P(W)<>1000 THEN NEXT :PRINT:PRINT "You haven't got one.":GOTO 268
703 PRINT:RETURN
800 FOR T=1 TO 2000:NEXT :RETURN
1000 IF B0$<>"GAME" THEN 236 ELSE PRINT"INSERT DISK ... ENTER FILENAME:";:GOSUB 404:FI$=LEFT$(A0$,8)+".SAV"
1005 OPEN "O",#1,FI$
1010 WRITE #1,G,H,F,I,L,SC,MS,D,J,T(4,47),T(4,37),T(2,37),T(4,34),T(1,10)
1011 FOR C=0 TO 13:WRITE #1,O1$(C):WRITE #1,O2$(C):WRITE #1,P(C):NEXT:FOR C=1 TO 10:WRITE #1,M1$(C):WRITE #1,M2$(C):WRITE #1,N(C):NEXT
1020 CLOSE #1:PRINT"Press <ENTER> to resume."
1030 IF INKEY$="" THEN 1030 ELSE 268
2000 IF B0$<>"GAME" THEN 236 ELSE PRINT"INSERT DISK ... ENTER FILENAME:";:GOSUB 404:FI$=LEFT$(A0$,8)+".SAV"
2005 OPEN "I",#1,FI$:IF EOF(1) THEN 2015
2010 INPUT #1,G,H,F,I,L,SC,MS,D,J,T(4,47),T(4,37),T(2,37),T(4,34),T(1,10)
2011 FOR C=0 TO 13:INPUT #1,O1$(C):INPUT #1,O2$(C):INPUT #1,P(C):NEXT:FOR C=1 TO 10:INPUT #1,M1$(C):INPUT #1,M2$(C):INPUT #1,N(C):NEXT
2020 CLOSE #1:TD$="":PRINT"Press <ENTER> to resume."
2030 IF INKEY$="" THEN 2030 ELSE TD$="":GOTO 202
3000 IF C=0 OR C=7 OR C=11 THEN RETURN
4000 Q$="N1;N22;N33;N44;N55;N66;N77;N84;":FOR X=1 TO 15:NEXT:RETURN
 TD$="":GOTO 202
3000 IF C=0 OR C=7 OR C=11 THEN RETURN
4000 Q$="N1;N22;N33;N44;N55;N66;N77;N84;":FOR X=