5 DATA 11,6,16,7,23,10,26,3,27,15 
10 DATA 28,8,29,11,32,3,33,13,34,11
20 DATA 35,9,39,16,40,8,41,13,44,5
30 DATA 46,10,45,16,50,1,51,12,56,4
40 DATA 39,4,44,5,35,9,40,8,45,1,41,15,46,12,51,5,56,16
50 DATA 0,0
60 RANDOMIZE TIMER
100 REM--E.A.GALLETTA,PATCHOGUE-H.S.,4/22/69 EARTH SIENCE (BIICAC)
110 REM--PROGRAM ON CLIMATES  
120 REM--REWRITTEN--7/28/69--BASIC--<ROD> 
130 REM REVISED BY  TO NY PEREZ, WALT WHITMAN HS, 8-69 
140 REM RE-REVISED BY C.LOSIK 8-26-70
150 DIM L(56)  
160 READ N,L(N)
170 IF  N<>56  THEN  160
180 T=0 
190 PRINT"O.K., HERE ARE SOME VALUES FOR  THE PRECIPIATION (P) AND FOR 
200 PRINT"THE POTENTIAL EVAPOTRANSPIRATION (PE) OF AN AREA:"  
210 PRINT 
220 PRINT" ","MONTH"," P"," PE" 
230 PRINT" ","=====","=====","======" 
240 P=INT(10*RND(1))
250 IF P>6  THEN  240  
260 IF P<1  THEN  240
270 E=INT(10*RND(1))
280 IF E>4  THEN  270  
290 IF E<1 THEN 270
300 Z=5*E+6*P  
310 IF  (Z-21)*(Z-22)*(Z-17)*(Z-38)=0  THEN  240 
320 FOR I=1 TO 12 
330 PRINT" ",I,
340 IF P>1 THEN 360  
350 P1=12*COS(.261*I)^2+2*RND(1)
360 IF P<>2 THEN 380 
370 P1=12*SIN(.261*I)+2*RND(1) 
380 IF P<>3 THEN 400 
390 P1=2+3*RND(1)  
400 IF P<>4 THEN 420 
410 P1=2*RND(1) 
420 IF P<>5 THEN 440 
430 P1=7+10*RND(1) 
440 IF P<>6 THEN 460 
450 P1=3*COS(.5+.15*I)^2
460 PRINT INT(P1)
470 IF E>1 THEN 490  
480 E1=10*SIN(.261*I)^2 
490 IF E<>2 THEN 510 
500 E1=12*SIN(.261*I)^2 
510 IF E<>3 THEN 530 
520 E1=2*SIN(.5+.15*I)^2
530 IF E<>4 THEN 550 
540 E1=8+4*RND(1)  
550 T=T+INT(P1) 
560 PRINT INT(E1+(E1/10)*2) 
570 NEXT  I 
590 PRINT" TOTAL PRECIPITATION =";T;"INCHES"
610 PRINT"O.K., PLOT YOUR GRAPH ON THE PAPER PROVIDED TO YOU" 
620 PRINT"AND WHEN YOU ARE READY  TO  CONTINUE.... MERELY TYPE" 
630 PRINT"ANY NUMBER AND THE RETURN KEY.      "; 
640 INPUT Q 
650 PRINT 
660 PRINT"READY? GOOD, NOW TELL ME . . . DOES YOUR GRAPH SHOW THAT"  
670 PRINT"THE CLIMATE HAS DEFINITE WET AND DRY SEASONS (1=YES, 0=NO) "
680 INPUT  S
690 PRINT 
700 IF S=0 THEN 880  
710 IF  S<>1  THEN  660  
720 IF P<3 THEN 990  
730 B=0
740 GOSUB  1960
750 PRINT"TELL ME, IS THE CLIMATE [1] WET, [2] DRY, R [3] MODERATE ALL"  
760 PRINT"YEAR";  
770 INPUT  S
780 PRINT 
790 IF S=1 THEN 920  
800 IF S=3 THEN 960  
810 IF  S<>2  THEN  750  
820 IF T<13 THEN 1130 
830 IF T>80 THEN 860 
840 GOSUB 1950 
850 GOTO 1140
860 GOSUB 1910 
870 GOTO 1140
880 IF P>2 THEN 750  
890 IF P=2 THEN 820  
900 GOSUB 1910 
910 GOTO 990
920 IF T>80 THEN 1130 
930 IF T>=13 THEN 840 
940 GOSUB 1930 
950 GOTO 1140
960 IF (T-13)*(80-T)>=0 THEN 1130 
970 IF T<13 THEN 940 
980 IF T>80 THEN 860 
990 PRINT"TELL ME, WHICH IS THE WET SEASON, [1] THE WINTER OR [2] THE" 
1000 PRINT"SUMMER"; 
1010 PRINT 
1020 INPUT  S
1030 PRINT 
1040 IF S=1 THEN 1090  
1050 IF  S<>2  THEN  990  
1060 IF P=2 THEN 1130  
1070 GOSUB 1910 
1080 GOTO 1140
1090 IF P=1 THEN 1130  
1100 GOSUB 1910 
1110 GOTO 1140
1120 PRINT 
1130 PRINT"NICE GOING, SMARTY PANTS. KEEP UP THE GOODWORK."  
1140 PRINT"BY CHECKING THE PE CURVE ON YOUR GRAPH, WOUD YOU SAY THAT THE" 
1150 PRINT"SUMMERS ARE [1] HOT, [2] WARM, OR [3] COOL" 
1160 INPUT  S
1170 PRINT 
1180 IF S=2 THEN 1260  
1190 IF S=3 THEN 1300  
1200 IF  S<>1  THEN  1130  
1210 IF E=2 THEN 1320  
1220 IF E=4 THEN 1320  
1230 IF  E=1  THEN  1320
1240 GOSUB 1910 
1250 GOTO 1330
1260 IF E=1 THEN 1320  
1270 IF E<>3 THEN 1240 
1280 GOSUB 1950 
1290 GOTO 1330
1300 IF E=3 THEN 1320  
1310 IF E<>3 THEN 1240 
1320 PRINT"YOU HAVE RESTORED MY FAITH IN TEENAGERS."
1330 PRINT"FROM THE SAME INFOR MATION (PE GRAPH), WOULD YOU SAY THAT THE"
1340 PRINT"WINTERS ARE [1] COLD, [2] MILD, OR [3] WARM";
1350 INPUT  S
1360 PRINT 
1370 IF S=2 THEN 1450  
1380 IF S=3 THEN 1490  
1390 IF  S<>1  THEN  1330  
1400 IF E<3 THEN 1520  
1410 GOSUB 1930 
1420 GOTO 1530
1430 GOSUB 1950 
1440 GOTO 1530
1450 IF E=3 THEN 1520  
1460 IF E=4 THEN 1430  
1470 GOSUB 1910 
1480 GOTO 1530
1490 IF E=3 THEN 1410  
1500 IF E=4 THEN 1530  
1510 GOTO 1470
1520 PRINT"IT WARMS MY HEART  TO  HEAR YOU SAY THAT. GOOD GOING."
1530 PRINT 
1540 PRINT"WELL, BY NOW YOU MUST HAVE AN INKLING AS  TO  THE TYPE OF" 
1550 PRINT"CLIMATE WE HAVE HERE. BELOW IS A COMPLETE LISTING OF ALL THE  
1560 PRINT"CLIMATES IN THE WORLD. REFER  TO  THEM BY THEIR NUMBER ONLY." 
1570 PRINT 
1580 PRINT 
1590 PRINT"NUMBER","NAME OF CLIMATE"
1600 PRINT"======","==============="
1610 PRINT"1","TROPICAL RAINFOREST" 
1620 PRINT"2","TROPICAL EAST COAST" 
1630 PRINT"3","TROPICAL MONSOON"
1640 PRINT"4","TROPICAL SAVANNA"
1650 PRINT"5","TROPICAL DESERT" 
1660 PRINT"6","MEDITERRANEAN"  
1670 PRINT"7","MARINE WEST COAST"  
1680 PRINT"8","HUMID CONTINENTAL"  
1690 PRINT"9","HUMID SUBTROPICAL"  
1700 PRINT"10","MIDDLE LATITUDE GRASSLANDS" 
1710 PRINT"11","MIDDLE LATITUDE DESERT" 
1720 PRINT"12","SUBARTIC CLIMATES" 
1730 PRINT"13 OR 14","HIGHLAND CLIMATES"
1740 PRINT" ","(TROPICAL OR MIDDLE LATITUDES)" 
1750 PRINT"15","POLAR TUNDRA"  
1760 PRINT"16","POLAR ICECAP"  
1770 PRINT 
1780 PRINT"WHAT IS THE NUMBER OF THE CLIMATE WE HAVE (WE'LL ACCEPT THE" 
1790 PRINT "FACT THAT THEY MAY OVERLAP)";  
1800 INPUT S 
1810 PRINT 
1820 PRINT 
1830 PRINT 
1840 IF S=L(Z) THEN 1880  
1850 PRINT"MY SUGGESTION - STICK  TO  LANGUAGES OR SOCIAL STUDIES."  
1860 PRINT"YOU SHOULD HAVE SAID";L(Z);". GOOD DAY  TO  YOU." 
1870 STOP
1880 PRINT"YOUR FORTUNE AS A METEOROLOGIST IS BUDDING. IT WAS" 
1890 PRINT"VERY NICE  TO  WORK WITH YOU. SO LONG."  
1900 STOP  
1910 B=1 
1920 GOTO 1960  
1930 B=2 
1940 GOTO  1960  
1950 B=3 
1960 PRINT"AW C'MON, YOU COULDN'T POSSIBLY MEAN THAT..."  
1970 PRINT"YOU SHOULD HAVE SAID";B 
1980 PRINT 
1990 RETURN 
2060 END
,44,5