1 RANDOMIZE TIMER
2 DIM T(25),P(25)
5 cls:WIDTH 80
10 PRINT TAB(33);"BOMBARDMENT":PRINT
20 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
30 PRINT:PRINT:PRINT
100 PRINT "YOU ARE ON A BATTLEFIELD WITH 4 PLATOONS AND YOU"
110 PRINT "HAVE 25 OUTPOSTS AVAILABLE WHERE THEY MAY BE PLACED."
120 PRINT "YOU CAN ONLY PLACE ONE PLATOON AT ANY ONE OUTPOST."
130 PRINT "THE COMPUTER DOES THE SAME WITH ITS FOUR PLATOONS."
135 PRINT
140 PRINT "THE OBJECT OF THE GAME IS TO FIRE MISSILES AT THE"
150 PRINT "OUTPOSTS OF THE COMPUTER.  IT WILL DO THE SAME TO YOU."
160 PRINT "THE ONE WHO DESTROYS ALL FOUR OF THE ENEMY'S PLATOONS"
170 PRINT "FIRST IS THE WINNER."
180 PRINT
190 PRINT "GOOD LUCK... AND TELL US WHERE YOU WANT THE BODIES SENT!":GOTO 200
198 DIM P(25),T(25)
199 C=0:Q=0
200 PRINT "PRESS 1 IF YOU WOULD LIKE ME TO PLACE THE SHIPS
210 INPUT "OR ANYTHING ELSE TO PLACE YOUR OWN  SHIPS";W
220 IF W=1 THEN GOTO 250
230 PRINT "WHAT ARE YOUR FOUR POSITIONS";
240 INPUT G,H,K,L
241 IF G =H THEN 230
242 IF G =K THEN 230
243 IF G =L THEN 230
244 IF H =K THEN 230
245 IF H =L THEN 230
246 IF K =L THEN 230
247 GOTO 380
250 G=INT(RND(1)*25)+1
260 H=INT(RND(1)*25)+1
270 K=INT(RND(1)*25)+1
280 L=INT(RND(1)*25)+1
290 IF G=H THEN 260
300 IF G=K THEN 270
310 IF G=L THEN 280
320 IF H=K THEN 270
330 IF H=L THEN 280
340 IF K=L THEN 280
380 C=INT(RND(1)*25)+1
390 D=INT(RND(1)*25)+1
400 E=INT(RND(1)*25)+1
410 F=INT(RND(1)*25)+1
420 IF C=D THEN 390
430 IF C=E THEN 400
440 IF C=F THEN 410
450 IF D=E THEN 400
460 IF D=F THEN 410
470 IF E=F THEN 410
500 PRINT "WHERE DO YOU WISH TO FIRE YOUR MISSILE";
510 INPUT Y
511 IF Y <1 OR Y >25 THEN 500
512 IF INT(Y)>Y THEN 500
513 IF T(Y) =1 THEN PRINT "THIS POSITION HAS ALREADY BEEN FIRED AT.":GOTO 500
520 IF Y=C THEN 710
530 IF Y=D THEN 710
540 IF Y=E THEN 710
550 IF Y=F THEN 710
560 GOTO 630
570 X =INT(RND(1)*25)+1
571 IF P(X) =1 THEN 570
575 GOTO 1160
580 IF X=G THEN 920
590 IF X=H THEN 920
600 IF X=L THEN 920
610 IF X=K THEN 920
620 GOTO 670
630 PRINT "HA, HA YOU MISSED. MY TURN NOW:"
640 PRINT: PRINT: GOTO 570
670 PRINT "I MISSED YOU. YOU DIRTY RAT. I PICKED"X
680 PRINT: PRINT: GOTO 500
710 Q=Q+1
720 IF Q=4 THEN 890
730 PRINT "YOU GOT ONE OF MY OUTPOSTS!"
740 IF Q=1 THEN 770
750 IF Q=2 THEN 810
760 IF Q=3 THEN 850
770 PRINT "ONE DOWN, THREE TO GO."
780 PRINT: PRINT: GOTO 570
810 PRINT "TWO DOWN, TWO TO GO."
820 PRINT: PRINT: GOTO 570
850 PRINT "THREE DOWN, ONE TO GO."
860 PRINT: PRINT: GOTO 570
890 PRINT "YOU GOT ME, I'M GOING FAST. BUT I'LL GET YOU WHEN"
900 PRINT "MY TRANSISTORS RECUPERATE!"
910 GOTO 1250
920 Z=Z+1
930 IF Z=4 THEN 1110
940 PRINT "I GOT YOU. IT WON'T BE LONG NOW. POST";X;"WAS HIT."
950 IF Z=1 THEN 990
960 IF Z=2 THEN 1030
970 IF Z=3 THEN 1070
990 PRINT "YOU HAVE ONLY THREE OUTPOSTS LEFT."
1000 PRINT: PRINT: GOTO 500
1030 PRINT "YOU HAVE ONLY TWO OUTPOSTS LEFT."
1040 PRINT: PRINT: GOTO 500
1070 PRINT "YOU HAVE ONLY ONE OUTPOST LEFT."
1080 PRINT: PRINT: GOTO 500
1110 PRINT "YOU'RE DEAD. YOUR LAST OUTPOST WAS AT";X;". HA, HA, HA."
1120 PRINT "BETTER LUCK NEXT TIME."
1130 GOTO 1250
1150 GOTO 1235
1160 P=P+1
1170 N=P-1
1190 T(Y) =1
1220 P(X)=1
1230 GOTO 580
1250 INPUT "DO YOU WANT TO PLAY AGAIN?";A$
1260 IF LEFT$(A$,1)="Y"THEN CLEAR:GOTO 198
1270 END
